Kako da preuzmem COOKIE iz browsera u Flash Builder?

Code:

private function prikupiPromenljive():void {

     //Definišeš zahtev i funkciju za učitavanje URL-a

     var request:URLRequest = new URLRequest("http://www.tvojsajt.rs/nekiphp.php");
     var urlLoader:URLLoader = new URLLoader();

     //"urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES" ti je obavezno da 
     //staviš ako hoćes da ti Flex aplikacija učita text kao skup promenljivih.
     //Ako to ne definišeš, Flex će učitati text ili PHP output kao String.

     urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;

     //Postaviš listener tako da Flex aplikacija "sluša" kada je učitavanje zavrseno ili ako nastane neka greška pri učitavanju.

     urlLoader.addEventListener(Event.COMPLETE, prikaziPromenljive);
     urlLoader.addEventListener(IOErrorEvent.IO_ERROR,greskaPriUcitavanju);

     //Učitavamo link pomoću komande "load"

     urlLoader.load(request);
}

private function greskaPriUcitavanju(err:IOErrorEvent):void {
     trace("URL ne postoji ili ne može biti učitan");
}

private function prikaziPromenljive(event:Event):void {

     //Ako hoćes da učitas podatke dobijeno od strane servera,
     //moraš napraviti URLLoader da bi mogao da učitas podatke
     //koji je dobio "urlLoader" u prethodnoj funkciji

     var loader:URLLoader = URLLoader(event.target);

     //Podaci su učitani u svojini zvano "data" i iz njih čitas podatke.
     //Iz "data" čitamo promenljive "korisnickoime" i "lozinka" koje smo definisali u PHP-u
     //"if (loader.data.korisnickoime && loader.data.lozinka)" nije potrebno,
     //ali bi bilo poželjno da znaš da li su ispravno učitani podaci.
     //Možda se nekad desi da Flex aplikacija dobro učita URL, a nema podataka.

     if (loader.data.korisnickoime && loader.data.lozinka) {
          //Izbacujemo podatke u debugger koristeći trace(); komandu
          trace(loader.data.korisnickoime);
          trace(loader.data.lozinka);
     }
}

Code:

// Proveravaš da li kolačić na odgovarajućem domenu postoji
if ($_COOKIE['korisnickoime'] && $_COOKIE['lozinka']) {
     //Ova funkcija radi output kolačića, kao recimo "korisnickoime=divijan&lozinka=12345"
     echo "korisnickoime=".$_COOKIE['korisnickoime']."&lozinka=".$_COOKIE['lozinka']
}