Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.

Otvaranje formi,na koji nacin

[es] :: Pascal / Delphi / Kylix :: Otvaranje formi,na koji nacin

Strane: 1 2 3

[ Pregleda: 9808 | Odgovora: 55 ] > FB > Twit

Postavi temu Odgovori

Autor

Pretraga teme: Traži
Markiranje Štampanje RSS

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Otvaranje formi,na koji nacin12.11.2013. u 21:06 - pre 126 meseci
Posto sam u nedoumici oko otvaranja formi,imam jedno pitanje....Kako otvarate drugu formu,jel preko Form1.show; ili preko sledeceg koda....
procedure TFrmPriznanje.DBGrid1DblClick(Sender: TObject);
var
F: TFrmPotvrda;
begin
F:= TFrmPotvrda.Create(nil);

try

F.Showmodal;

finally
f.Free;
end;
end;

end.

gde ovu formu prebacujem u available forms,u delu options

Dakle,sta od ova dva je bolje i sta je skolski....
 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin12.11.2013. u 22:25 - pre 126 meseci
Nisam siguran na sta tacno mislis, posto pod jednim podrazumevas Form1.Show(), a onda pod drugim prikazujes citav kod u kome prvo kreiras instancu forme a zatim koristis F.ShowModal() - ove dve stvari nisu iskljucive. Da li ces koristiti Show() ili ShowModal() zavisi od toga sta zelis da postignes tom formom koju prikazujes, a kreiranje forme dinamicki mozes raditi i u jednom i u drugom slucaju (doduse, ne sa ovim istim kodom).

Racunam da je pitanje da li koristiti (1) automatski (staticki) kreirane forme (one koje se npr. nalaze u Project > Options > Forms > Auto-create forms) ili ih odatle (2) prebaciti desno u "Available forms" pa ih kreirati dinamicki - u ovom slucaju je resenje pod (2) generalno bolje, osim mozda u specificnim slucajevima.

Forme koje se nalaze unutar "Auto-create forms" se automatski kreiraju po pokretanju aplikacije (sto se moze videti u Project > View Source, pa obratiti paznju na Application.CreateForm() i parametre koje uzima), cime se dodeljuju (zauzimaju) resursi i kreira jedna instanca forme (obicno skrivena, ukoliko nije drugacije podeseno), i to bez obzira hocemo li je uskoro koristiti ili ne. Ovim formama mozemo pristupiti bilo kada u toku rada aplikacije bez potrebe da ih prvo sami kreiramo (i pod uslovom da ih nismo u medjuvremenu sami unistili - ne zatvorili, jer ih zatvaranje obicno samo skriva, ne unistava (Free())).

Sa druge strane, forme unutar "Available forms" iz ugla aplikacije ne postoje dok ih sami ne kreiramo (kao u primeru iz tvog koda), i samim tim ne zauzimaju bespotrebno resurse racunara sve do trenutka dok nam zaista nisu potrebne (opet pod uslovom da ih programer na pravi nacin i u pravo vreme kreira).

Prvi nacin ("Auto-create forms") nudi (uglavnom za pocetnike) prostije, brze i lakse resenje baratanja sa vise formi, ali moze biti neoptimizovan i bespotrebno trositi resurse racunara, dok drugi ("Available forms") predstavlja mnogo elegantnije resenje (i bezbolnije po resurse racunara), ali zahteva malo paznje od strane programera koji mora da vodi racuna gde i kad forme kreira/unistava (sto je i inace slucaj i kada se radi sa bilo kojim drugim objektima, ne samo tipa forme).

E sad, ako aplikacija ima par prostih formi, onda ti realno nije toliko ni vazno kako ces raditi (po pitanju resursa) - drugi nacin i dalje predstavlja (po meni) bolje resenje (skolsko), samo je pitanje da li ces imati vremena/volje da to odradis kako treba (jer ispadne malo vise posla). Medjutim, ako je u pitanju poslovna aplikacija koja sadrzi desetine ili stotine (moguce i kompleksnih) formi, onda mislim da je drugi nacin jedini ispravan - osim ako ne zelis da cekas dva dana na pokretanje aplikacije, pritom zauzimajuci pola resursa racunara :)
 
Odgovor na temu

reiser

Član broj: 7895
Poruke: 2314



+102 Profil

icon Re: Otvaranje formi,na koji nacin12.11.2013. u 22:50 - pre 126 meseci
Da se nadovezem na post iznad mene, jedno od najboljih resenja (bar po meni) je da napises staticku public proceduru koja ce pokrenuti formu. Dakle, to bi trebalo da izgleda otprilike ovako:

Code:

type
  TfrmSecond = class(TForm)
  private
  public
    class function RunModal: Integer;
  end;

var
  frmSecond: TfrmSecond;

implementation

class function TfrmSecond.RunModal: Integer;
begin
  Application.CreateForm(TfrmSecond, frmSecond);
  try
    result := frmSecond.ShowModal;
  finally
    frmSecond.Free;
  end;
end;


I onda iz drugih formi otvaras formu sa TfrmSecond.RunModal.
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 09:22 - pre 126 meseci
Hvala na odgovorima...ja sam do sada radio na prvi nacin,jer je svakako laksi,a nisam imao vise od 6-7 formi,maksimalno 10...Pitanje sam postavio,jer hocu da predjem na ovaj drugi nacin,bas zbog cuvanja resursa racunara....Ako otvorim jednu formu(Form1),u kojoj su dbgrid1,u query1,i dataset....pa iz nje otvorim form2,u kojoj se nalaze text box1,textbox2,itd....i hocu da iz tih textbox promenim,dbgrid1 u prvoj formi....to mogu samo preko prvog nacina,ali preko drugog ne znam....Dakle, u Form2,postoji i dugme koje zatvara tu formu,a ostavlja formu 1,i promeni dbgrid sa textbox iz druge forme.....Kako to odraditi pomocu onog drugog nacina,skolskog primera....Hvala
 
Odgovor na temu

_deran_

Član broj: 69493
Poruke: 252
*.dynamic.sbb.rs.



+1 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 15:57 - pre 126 meseci
Forme ne bi trebalo oslobadjati sa Free nego sa Release.
 
Odgovor na temu

reiser

Član broj: 7895
Poruke: 2314



+102 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 17:53 - pre 126 meseci
Savrseno je bezbedno da se forma osloadja pomocu .Free(). Jedini scenario gde treba da se koristi .Release() je ako formu oslobadjas u sred nekog njenog event handlera.
 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 18:42 - pre 126 meseci
Citat:
reiser:
Da se nadovezem na post iznad mene, jedno od najboljih resenja (bar po meni) je da napises staticku public proceduru koja ce pokrenuti formu. Dakle, to bi trebalo da izgleda otprilike ovako:

Code:

type
  TfrmSecond = class(TForm)
  private
  public
    class function RunModal: Integer;
  end;

var
  frmSecond: TfrmSecond;

implementation

class function TfrmSecond.RunModal: Integer;
begin
  Application.CreateForm(TfrmSecond, frmSecond);
  try
    result := frmSecond.ShowModal;
  finally
    frmSecond.Free;
  end;
end;


I onda iz drugih formi otvaras formu sa TfrmSecond.RunModal.

Par komentara - prvo, mislim da ne bi trebalo da eksplicitno koristis Application.CreateForm() jer to nije isto sto i TForm.Create(), barem ako govorimo o prostom kreiranju formi. Application.CreateForm() moze imati dodatne (nezeljene?) efekte, npr. ukoliko jos uvek nije (iz bilo kog razloga) dodeljena glavna forma aplikacije prvi poziv Application.CreateForm() ce formu koja se kreira uzeti za glavnu. Dalje, Application.CreateForm() automatski postavlja aplikaciju za vlasnika forme, sto nam takodje mozda ne odgovara.

Drugo, upotreba globalne promenljive "frmSecond" je sumnjiva. U zavisnosti od njene primene (unutar klase, na sta mozemo uticati, ali i primene same klase u programu, na sta potencijalno ne mozemo uticati (!)) moze doci do pucanja aplikacije (Access Violation). Globalne promenljive bi u globalu trebalo izbegavati :)

Ne menjajuci pocetnu ideju, mislim da bi sledeca implementacija bila bolje resenje:
Code:

type
  TfrmSecond = class(TForm)
  private
  public
    class function RunModal(): Integer;
  end;

implementation

class function TfrmSecond.RunModal(): Integer;
var
  frmSecond: TfrmSecond;
begin
  frmSecond := TfrmSecond.Create(nil)
  try
    result := frmSecond.ShowModal;
  finally
    frmSecond.Free;
  end;
end;

 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 18:54 - pre 126 meseci
Citat:
_deran_: Forme ne bi trebalo oslobadjati sa Free nego sa Release.
Citat:
reiser: Savrseno je bezbedno da se forma osloadja pomocu .Free(). Jedini scenario gde treba da se koristi .Release() je ako formu oslobadjas u sred nekog njenog event handlera.

Slozio bih se sa reiser-om (pogotovo ako govorimo o modalnim formama), i jos dodao da koriscenje Release() umesto Free() cesce moze sugerisati da je u pitanju los dizajn, zbog cega ce nas kasnije samo vise boleti glava.

Release() je nista vise do odlozeno Free(), u fazonu "nemoj unistiti formu sada, nego malo posle", gde ovo "malo posle" moze biti ko zna kad - obicno nakon obrade svih poruka koje su na formu cekale, pa na kraju i same poruke koju smo poslali preko Release(), ali sustina je da to vise ne zavisi od nas, vise nemamo nad tim kontrolu. Verujem da (mozda) moze naci primenu, ali mi je Free() mnogo sigurnije (da ne kazem bolje :) resenje.
 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 19:29 - pre 126 meseci
Citat:
popmilan76: Hvala na odgovorima...ja sam do sada radio na prvi nacin,jer je svakako laksi,a nisam imao vise od 6-7 formi,maksimalno 10...Pitanje sam postavio,jer hocu da predjem na ovaj drugi nacin,bas zbog cuvanja resursa racunara....Ako otvorim jednu formu(Form1),u kojoj su dbgrid1,u query1,i dataset....pa iz nje otvorim form2,u kojoj se nalaze text box1,textbox2,itd....i hocu da iz tih textbox promenim,dbgrid1 u prvoj formi....to mogu samo preko prvog nacina,ali preko drugog ne znam....Dakle, u Form2,postoji i dugme koje zatvara tu formu,a ostavlja formu 1,i promeni dbgrid sa textbox iz druge forme.....Kako to odraditi pomocu onog drugog nacina,skolskog primera....Hvala

Ovo je sad pitanje dizajna (arhitekture) aplikacije, i moze se resiti na vise nacina.

Moze ovako:
Code:

procedure TFrmPriznanje.DBGrid1DblClick(Sender: TObject);
var
  F: TFrmPotvrda;
begin
  F:= TFrmPotvrda.Create(nil);
  try
    F.ShowModal();
    DbGrid1... := F.TextBox1.Text; // ovo korigovati shodno tome gde zelis da pises u DbGrid1 i odakle da citas iz TextBox1
  finally
    F.Free();
  end;
end;

Ili, recimo, koristeci event handler-e.
Code:

procedure TFrmPriznanje.Form2TextBoxChange(Sender: TObject);
begin
  // ovde sad mozes dobiti vrednost iz TextBox1 kao
  // (Sender as TEdit).Text
  // ili gde se vec tekst nalazi (ovde je dat primer ako je TextBox1 tipa TEdit)
  //
  // primer:
  DbGrid1... := (Sender as TEdit).Text;
end;

procedure TFrmPriznanje.DBGrid1DblClick(Sender: TObject);
var
  F: TFrmPotvrda;
begin
  F:= TFrmPotvrda.Create(nil);
  try
    F.TextBox1.OnChange := Form2TextBoxChange; // pozovi Form2TextBoxChange() na svaku promenu vrednosti TextBox1 koji se nalazi na Form2
    F.ShowModal();
  finally
    F.Free();
  end;
end;

 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 20:22 - pre 126 meseci
Zar ne treba prvo napravim insert ili edit database....kao ovako

procedure TFrmPotvrda.BitBtn1Click(Sender: TObject);
var
F: TFrmPriznanje;
begin
F:= TFrmPriznanje.Create(nil);
try

F.ShowModal;
f.Query2.DataSource.DataSet.Edit ;
f.DBGrid1.Columns[5].field.AsString := combobox1.Text ;
f.Query2.DataSource.DataSet.Post ;

finally
F.Free;
end;
end;

end.
 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 20:39 - pre 126 meseci
Zato sam i napisao da korigujes shodno svojim potrebama, ja sam ti samo pokazao kako da uzmes vrednost sa druge forme :)
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin13.11.2013. u 20:50 - pre 126 meseci
Mozes pogledati moj kod,mislim da u njemu nesto ne valja....prijavljuje gresku...i kako da zatvorim form2,da mi ostane form1 sa promenom...Sve mi se vise cini da cu nastaviti da radim sa svim formama kao autocreate....

Dakle ,zanima me kako to sve funkcionise,,,,gde se forma kreira,gde nestaje,i tako to....

[Ovu poruku je menjao popmilan76 dana 14.11.2013. u 00:00 GMT+1]
 
Odgovor na temu

((BugA))
Igor Djordjevic
Bor, Srbija

Član broj: 29241
Poruke: 196
*.dynamic.sbb.rs.

ICQ: 66516695
Sajt: www.MalamutKlub.com


+17 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 01:13 - pre 126 meseci
Deder bar napisi koju gresku prijavljuje i gde, davno nisam radio sa ovim data-aware komponentama pa stvarno ne bih znao napamet :) Mozda ne bi bilo lose ni da otvoris posebnu temu za probleme sa menjanjem vrednosti unutar TDBGrid-a, kako bi se ovde drzali diskusije o formama.

Evo dodatnog objasnjenja, malo cu promeniti imena da bi bilo jasnije o cemu se radi:
Code:
procedure TForm1.DBGrid1DblClick(Sender: TObject); // procedura se poziva (recimo) na dupli klik unutar DBGrid1 na formi 1
var
  Forma2: TForm2;
begin
  Forma2 := TForm2.Create(nil); // kreiramo formu pod imenom Forma2, tipa TForm2, forma je sakrivena (ne vidi se na ekranu)
  try
    Forma2.ShowModal(); // prikazujemo formu 2 (pojavljuje se na ekranu) kao modalnu 
      // (znaci da nemamo pristup drugim formama aplikacije dok ovu formu ne zatvorimo)
      // Takodje, izvrsavanje ove metode (DBGrid1DblClick()) se ovde zaustavlja, sve do trenutka dok ne
      // zatvorimo formu 2, nakon cega se izvrsavanje nastavlja u sledecem redu

    Self.DBGrid1.DataSource.DataSet.Edit; // omoguci izmenu podataka

    Self.DBGrid1.DataSource.DataSet.FieldByName('ImePolja').AsString := Forma2.TextBox1.Text; // nastavak izvrsavanja
      // (nakon zatvaranja forme 2), Forma2 i dalje postoji,
      // samo je sada (ponovo) skrivena (da, njenim zatvaranjem je nismo unistili, 
      // vec samo sakrili - osim ako nismo namestili da se prilikom zatvaranja i unisti...)
      // Dokle god formu 2 ne unistimo, imamo najnormalniji pristup svim njenim
      // osobinama / vrednostima, sto se vidi iz ovog primera gde citamo
      // vrednost Text iz komponente TextBox1 koja se nalazi na formi 2, i dodeljujemo je
      // komponenti DbGrid1 koja se nalazi na formi 1 (unutar cije se procedure nalazimo,
      // pa u ovom slucaju Self predstavlja formu 1, tj. objekat klase TForm1)

    Self.DBGrid1.DataSource.DataSet.Post; // upisi izmene u bazu
  finally
    Forma2.Free(); // kada nam Forma2 vise nije potrebna, unistavamo je i oslobadjamo resurse koje je koristila,
      // nakon ovoga Forma2 vise ne postoji i ne mozemo joj pristupiti (niti citati vrednosti sa nje)
  end;
end;
 
Odgovor na temu

captPicard
programer
more i planine

Član broj: 216084
Poruke: 1119



+19 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 11:10 - pre 126 meseci
Ako ti DBGrid ima isti datasource kao i druga forma gdje vučeš podatke, ne vidim potrebe da prvo puniš grid pa onda radiš post. Dovoljno je da post napraviš u drugoj formi i refreshas query kada se vratiš u prvu formu i podatak će biti tamo zapisan.
F
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 15:30 - pre 126 meseci
Imam otvorene dve forme,s tim sto mi je focus na drugoj....i sada u drugoj imam combobox1,i iz njega menjam dbgrid1 u prvoj formi

procedure TFrmPotvrda.BitBtn1Click(Sender: TObject);
var
Form2: TFrmPriznanje;
begin

Form2:= TFrmPriznanje.Create(nil);
try

Form2.ShowModal;
form2.DBGrid1.DataSource.DataSet.Edit ;
form2.DBGrid1.DataSource.DataSet.Fields[5].asstring := combobox1.Text ;
form2.DBGrid1.DataSource.DataSet.Post ;
finally

Form2.Free;

end;
end;


i posle ovoga mi nista ne pojavljuje........i kada hocu da skinem form1,prikazuje gresku dataset is not ionsert or edit mode ili tako nesto.....

Gde gresim....


FrmPotvrda je u ovom slucaju Form1,a FrmPriznanje je Form2
 
Odgovor na temu

reiser

Član broj: 7895
Poruke: 2314



+102 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 15:46 - pre 126 meseci
Greska je u tome sto te promene u Form2 trebas da uradis pre nego sto pozoves ShowModal. ShowModal ti prekida izvrsavanje funkcije dok se forma ne zatvori, i sve ono sto radis nakon toga, radis na vec zatvorenoj formi. Dakle:

Code:

procedure TFrmPotvrda.BitBtn1Click(Sender: TObject);
var
  Form2: TFrmPriznanje;
begin
  Form2:= TFrmPriznanje.Create(nil);
  try
    Form2.DBGrid1.DataSource.DataSet.Edit;
    Form2.DBGrid1.DataSource.DataSet.Fields[5].asstring := combobox1.Text ;
    Form2.DBGrid1.DataSource.DataSet.Post;
    Form2.ShowModal;
  finally
    Form2.Free;
  end;
end;
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 15:57 - pre 126 meseci
U ovom slucaju prikazuje da mi nije dataset u insertmode ili edit mode...


I kako da zatvorim prvu formu......
 
Odgovor na temu

reiser

Član broj: 7895
Poruke: 2314



+102 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 16:30 - pre 126 meseci
Tako sto uzmes knjigu/dokumentaciju/google u ruke i citas :) Mislim, uopste ne zelim da budem maliciozan, ali ono sto ti radis nije ispravan nacin da se uci programiranje.. Ne mozes da pises nesto tek-tako i da ocekujes da radi ispravno. Pravis pocetnicke greske i bez da se trudis da ih sam resis, pitas ovde, ljudi ti pomognu, ali ti i dalje nastavljas da pravis iste greske. Pokusaj da razumes zasto nesto ne radi i resis ga sam, tako ces najbrze napredovati. Za pocetak, identuj kod.
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 17:16 - pre 126 meseci
Nikoga ja ovde ne teram da mi pomogne....Naravno,sve je dobrovoljno,ako neko hoce,hoce,ako nece,nece...njegova stvar...Da sam to bilo gde nasao,ne bih pitao,jednostavno nisam nasao.....
 
Odgovor na temu

popmilan76

Član broj: 295089
Poruke: 1337
*.dynamic.sbb.rs.



+5 Profil

icon Re: Otvaranje formi,na koji nacin14.11.2013. u 17:36 - pre 126 meseci
Code:
procedure TForm1.DBGrid1DblClick(Sender: TObject); // procedura se poziva (recimo) na dupli klik unutar DBGrid1 na formi 1
var
Forma2: TForm2;
begin
Forma2 := TForm2.Create(nil); // kreiramo formu pod imenom Forma2, tipa TForm2, forma je sakrivena (ne vidi se na ekranu)
try
Forma2.ShowModal(); // prikazujemo formu 2 (pojavljuje se na ekranu) kao modalnu
// (znaci da nemamo pristup drugim formama aplikacije dok ovu formu ne zatvorimo)
// Takodje, izvrsavanje ove metode (DBGrid1DblClick()) se ovde zaustavlja, sve do trenutka dok ne
// zatvorimo formu 2, nakon cega se izvrsavanje nastavlja u sledecem redu

Self.DBGrid1.DataSource.DataSet.Edit; // omoguci izmenu podataka

Self.DBGrid1.DataSource.DataSet.FieldByName('ImePolja').AsString := Forma2.TextBox1.Text; // nastavak izvrsavanja
// (nakon zatvaranja forme 2), Forma2 i dalje postoji,
// samo je sada (ponovo) skrivena (da, njenim zatvaranjem je nismo unistili,
// vec samo sakrili - osim ako nismo namestili da se prilikom zatvaranja i unisti...)
// Dokle god formu 2 ne unistimo, imamo najnormalniji pristup svim njenim
// osobinama / vrednostima, sto se vidi iz ovog primera gde citamo
// vrednost Text iz komponente TextBox1 koja se nalazi na formi 2, i dodeljujemo je
// komponenti DbGrid1 koja se nalazi na formi 1 (unutar cije se procedure nalazimo,
// pa u ovom slucaju Self predstavlja formu 1, tj. objekat klase TForm1)

Self.DBGrid1.DataSource.DataSet.Post; // upisi izmene u bazu
finally
Forma2.Free(); // kada nam Forma2 vise nije potrebna, unistavamo je i oslobadjamo resurse koje je koristila,
// nakon ovoga Forma2 vise ne postoji i ne mozemo joj pristupiti (niti citati vrednosti sa nje)
end;
end;



Ovo mi se svidja sto je BUG odradio.....sasvim je okej,nego nije u potpunosti odradjeno.....i moze li da forme budu u available forems,a da se pokrecu sa obicnim form1show.
 
Odgovor na temu

[es] :: Pascal / Delphi / Kylix :: Otvaranje formi,na koji nacin

Strane: 1 2 3

[ Pregleda: 9808 | Odgovora: 55 ] > FB > Twit

Postavi temu Odgovori

Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.