Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 19.08.2004. u 22:46 · pre 270 meseci #1

Pošto u top temi nisam pronašao odgovor na moj problem molim pomoć.

Kako da iz fajla čitam text i recimo prvo liniju zapišem u TextBox1,drugu u
TextBox2, a sve ostale linije u TextBox3?

Nemam problema sa čitanjem liniju po liniju, ali kako da skombiniram ovo?

Nadam se, da mi zbog takvog bezveznog pitanje nečete odmah brisati temu.
Molim Vas, da mi je pustite bar toliko, da dobijem odgovor.

Hvala

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 02:38 · pre 270 meseci #2

Pojasni malo, nisam te bas razumeo, ali evo ti jedan koristan link

http://www.juicystudio.com/tutorial/vb/files.asp

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 10:51 · pre 270 meseci #3

Linije loadujes u niz stringova i posle radis sa nizom

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim arrLines()  As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)


    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        ReDim Preserve arrLines(NumLines)
        arrLines(NumLines) = oTextStream.ReadLine
    Wend

    oTextStream.Close

    Set oTextStream = Nothing
    Set oFSO = Nothing

    If NumLines >= 1 Then Text1.Text = arrLines(1)
    If NumLines >= 2 Then Text2.Text = arrLines(2)

    For i = 3 To NumLines
        Text3.Text = Text3.Text & arrLines(i) & vbCrLf
    Next

End Sub

Potpis

Blue Man Group

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 10:54 · pre 270 meseci #4

ili bez niza

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim strLine     As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)


    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend

    oTextStream.Close

    Set oTextStream = Nothing
    Set oFSO = Nothing


End Sub

Potpis

Blue Man Group

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 12:44 · pre 270 meseci #5

Hvala na primerima, ali ja još uvjek imam problem.
Do sada sam uvjek čitao fajle sa " Open "c:\XXX.txt" For Imput As ..."
i zato mi taj FSO pravi probleme.

Kad startujem tvoj primer, onda mi javi grešku:

Dim oFSO As Scripting.FileSystemObject

Greška: User - defined type not defined

Dali trebam neki DLL ili šta?

Molim još pomoć!

Hvala!

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 12:48 · pre 270 meseci #6

Treba ti referenca na Microsoft Scripting Runtime. (Project->References)

Potpis

Blue Man Group

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 13:08 · pre 270 meseci #7

Uspelo!!

Puno hvala na pomoći i lep pozdrav!

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 13:18 · pre 270 meseci #8

@mldenovicz. Ovo mi je malo neobicno. Cemu

Code:
While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend

Zar nije jednostavnije i brze (za izvrsavanje)

Code:
Text1.Text = oTextStream.ReadLine
Text2.Text = oTextStream.ReadLine
While Not oTextStream.AtEndOfStream
Text3.Text = Text3.Text & oTextStream.ReadLine & vbCrLf
Wend

Potpis

Nebojsa Milanovic:
-Trumpa smatram vrhunskim predsednikom i voleo bih da živim u državi na čijem je on čelu
-Rusija ne laže, ne vodi osvajačke ratove
-Trump je svetla tačka u USA blatu
-Elon Musk, možda najpametniji i najtrezveniji Amerikanac

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć 20.08.2004. u 13:29 · pre 270 meseci #9

@Shadowed:
U pravu si. Ovo sam pisao pre nego sto sam popio kafu (ako je neko opravdanje)

Nekad se bas nacudim kodu koji napisem.

EDIT: Samo sto ovo tvoje parce koda podrazumeva da u fajlu postoje bar dve linije

Potpis

Blue Man Group

Forum kao aplikacija na telefonu

Srodne teme