[es] - Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

andrejas33
MB-Slo

Član broj: 24831
Poruke: 50
*.dial-up.volja.net

Profil

Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{19.08.2004. u 21:46 - pre 239 meseci}

Pošto u top temi nisam pronašao odgovor na moj problem molim pomoć.

Kako da iz fajla čitam text i recimo prvo liniju zapišem u TextBox1,drugu u
TextBox2, a sve ostale linije u TextBox3?

Nemam problema sa čitanjem liniju po liniju, ali kako da skombiniram ovo?

Nadam se, da mi zbog takvog bezveznog pitanje nečete odmah brisati temu.
Molim Vas, da mi je pustite bar toliko, da dobijem odgovor.

Hvala

Odgovor na temu

djordje
Novi Sad

Član broj: 3704
Poruke: 1725
*.vdial.verat.net

+3 Profil

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 01:38 - pre 239 meseci}

Pojasni malo, nisam te bas razumeo, ali evo ti jedan koristan link

http://www.juicystudio.com/tutorial/vb/files.asp

Odgovor na temu

mladenovicz
Zeljko Mladenovic
Xoran Technologies, Inc., Ann Arbor, MI,
USA / Software Engineer
Ann Arbor, MI, USA

Član broj: 6598
Poruke: 2065
*.bg.wifi.vline.verat.net.

Jabber: mladenovicz@elitesecurity.org
ICQ: 95144142
Sajt: yubc.net/~mz

Profil

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 09:51 - pre 239 meseci}

Linije loadujes u niz stringova i posle radis sa nizom

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim arrLines()  As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)


    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        ReDim Preserve arrLines(NumLines)
        arrLines(NumLines) = oTextStream.ReadLine
    Wend

    oTextStream.Close

    Set oTextStream = Nothing
    Set oFSO = Nothing

    If NumLines >= 1 Then Text1.Text = arrLines(1)
    If NumLines >= 2 Then Text2.Text = arrLines(2)

    For i = 3 To NumLines
        Text3.Text = Text3.Text & arrLines(i) & vbCrLf
    Next

End Sub

Blue Man Group

Odgovor na temu

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 09:54 - pre 239 meseci}

ili bez niza

Code:

Private Sub Form_Load()
Dim oFSO        As Scripting.FileSystemObject
Dim oTextStream As Scripting.TextStream
Dim strLine     As String
Dim NumLines    As Long
Dim i           As Long

    NumLines = 0

    Set oFSO = New Scripting.FileSystemObject
    Set oTextStream = oFSO.OpenTextFile("C:\test.txt", _
                                           ForReading, _
                                           True, _
                                           TristateFalse)


    While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend

    oTextStream.Close

    Set oTextStream = Nothing
    Set oFSO = Nothing


End Sub

Blue Man Group

Odgovor na temu

andrejas33
MB-Slo

Član broj: 24831
Poruke: 50
*.dial-up.volja.net

Profil

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 11:44 - pre 239 meseci}

Hvala na primerima, ali ja još uvjek imam problem.
Do sada sam uvjek čitao fajle sa " Open "c:\XXX.txt" For Imput As ..."
i zato mi taj FSO pravi probleme.

Kad startujem tvoj primer, onda mi javi grešku:

Dim oFSO As Scripting.FileSystemObject

Greška: User - defined type not defined

Dali trebam neki DLL ili šta?

Molim još pomoć!

Hvala!

Odgovor na temu

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 11:48 - pre 239 meseci}

Treba ti referenca na Microsoft Scripting Runtime. (Project->References)

Blue Man Group

Odgovor na temu

andrejas33
MB-Slo

Član broj: 24831
Poruke: 50
*.dial-up.volja.net

Profil

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 12:08 - pre 239 meseci}

Uspelo!!

Puno hvala na pomoći i lep pozdrav!

Odgovor na temu

Shadowed
Vojvodina

Član broj: 649
Poruke: 12848

+4784 Profil

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 12:18 - pre 239 meseci}

@mldenovicz. Ovo mi je malo neobicno. Cemu

Code:
While Not oTextStream.AtEndOfStream
        NumLines = NumLines + 1
        strLine = oTextStream.ReadLine
        Select Case NumLines
            Case 1
                Text1.Text = strLine
            Case 2
                Text2.Text = strLine
            Case Is > 2
                Text3.Text = Text3.Text & strLine & vbCrLf
        End Select
    Wend

Zar nije jednostavnije i brze (za izvrsavanje)

Code:
Text1.Text = oTextStream.ReadLine
Text2.Text = oTextStream.ReadLine
While Not oTextStream.AtEndOfStream
Text3.Text = Text3.Text & oTextStream.ReadLine & vbCrLf
Wend

Nebojsa Milanovic: Što se tiče Trumpa, smatram ga vrhunskim predsednikom i voleo bih da živim u državi na čijem je on čelu.
Nebojsa Milanovic: Rusija ne laže, ne vodi osvajačke ratove
Nebojsa Milanovic: Trump je svetla tačka u USA blatu.

Odgovor na temu

Re: Čitanje texta iz fajla i zapisivanje u više textBox-a Molim pomoć

^{20.08.2004. u 12:29 - pre 239 meseci}

@Shadowed:
U pravu si. Ovo sam pisao pre nego sto sam popio kafu (ako je neko opravdanje)

Nekad se bas nacudim kodu koji napisem.

EDIT: Samo sto ovo tvoje parce koda podrazumeva da u fajlu postoje bar dve linije

Blue Man Group

Odgovor na temu