Windows defender i autostart program u Visti

Code:


uses
  JclShell, JclFileUtils;

function ShellLinkPerform(const ATarget: string; const AFolder: Integer; const AOperation: Char): Boolean;
var
  DoUninitialize: Boolean;
  Temp: TShellLink;
  LinkPath: string;
  fv: TJclFileVersionInfo;

  function MatchLinkTarget: Boolean;
  var
    lpFindFileData: TWIN32FindData;
    hFindFile: THandle;
  begin
    Result := False;
    // Ispitujemo sve fajlove tj. linkove u datom folderu i gledamo da li neki od
    // tih linkova (shortcutova) upucuje na isti target kao i ovaj prosledjeni
    hFindFile := FindFirstFile(PChar(LinkPath + '*'), lpFindFileData);
    if hFindFile <> INVALID_HANDLE_VALUE then
    repeat
      if (lpFindFileData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY) <> FILE_ATTRIBUTE_DIRECTORY then
      begin
        if Succeeded(ShellLinkResolve(LinkPath + lpFindFileData.cFileName, Temp)) then
        begin
          if CompareText(PathGetLongName(Temp.Target), ATarget) = 0 then
          begin
            LinkPath := LinkPath + lpFindFileData.cFileName;
            Result := True;
          end;

          ShellLinkFree(Temp);
        end;
      end;
    until Result or not Windows.FindNextFile(hFindFile, lpFindFileData);

    Windows.FindClose(hFindFile);
  end;
begin
  // Procedura za pravljenje, proveru postojanja ili brisanje shell linka (shortcuta).
  // AFolder je CSIDL oznaka foldera u windowsu (Desktop, StartMenu, StartUp...)
  // AOperation je operacija, A(dd), Q(query), D(elete)
  DoUninitialize := Succeeded(CoInitialize(nil));

  // Najpre proveravamo da li u ciljnom folderu vec postoji shortcut na prosledjeni target
  LinkPath := IncludeTrailingBackslash(GetSpecialFolderLocation(AFolder));
  Result := MatchLinkTarget;

  case AOperation of
    'A':
    begin
      if Result then
        Result := False // Link vec postoji nemamo sta da dodamo
      else begin
        // Dodajmo link u folder, LinkPath vec sadrzi putanju do Foldera, dodajmo mu i filename
        LinkPath := LinkPath + ChangeFileExt(ExtractFileName(ATarget), '.lnk');
        FillChar(Temp, SizeOf(TShellLink), 0);

        fv := TJclFileVersionInfo.Create(ATarget);
        try
          if fv.FileDescription <> '' then
            Temp.Description := fv.FileDescription
          else
            Temp.Description := ExtractFileName(ATarget);
        finally
          fv.Free;
        end;

        Temp.WorkingDirectory := ExtractFilePath(ATarget);
        Temp.Target := ATarget;

        Result := Succeeded(ShellLinkCreate(Temp, LinkPath));

        ShellLinkFree(Temp);
      end;
    end;

    'D':
    begin
      if Result then // Ako postoji link na prosledjeni target, brisemo ga
        Result := Windows.DeleteFile(PChar(LinkPath));
    end;

    'Q': ; // Nemamo sta da radimo, vec je utvrdjeno da li link postoji
  end;

  if DoUninitialize then
    CoUninitialize;
end;

upotreba:

  // Da li program treba startovati sa Windowsom, zavisno od korisnikovog odabira
  // dodajemo ili brisemo shortcut iz StartUpa.
  if chkbxStartUp.Checked then
    UtilsEx.ShellLinkPerform(ParamStr(0), CSIDL_STARTUP, 'A')
  else
    UtilsEx.ShellLinkPerform(ParamStr(0), CSIDL_STARTUP, 'D');

Code:

  procedure SetRunAsAdminAppCompatFlag(AppPathExeName: String);
  var
    Reg: TRegistry;
  begin
    Reg := TRegistry.Create(KEY_WRITE);
    try
      Reg.RootKey := HKEY_CURRENT_USER;
      if Reg.OpenKey('Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers', True) then
        Reg.WriteString(AppPathExeName, 'RUNASADMIN');
    finally
      Reg.CloseKey;
      Reg.Free;
    end;
  end;