iscitavanje ip adresa u lan-u

Code:

Option Explicit

Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, ByVal nSize As Long) As Long
Private Declare Sub GetStartupInfo Lib "kernel32" Alias "GetStartupInfoA" (lpStartupInfo As STARTUPINFO)
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As Any, lpThreadAttributes As Any, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function SetWindowText Lib "user32" Alias "SetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String) As Long
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, lpOverlapped As Any) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Type SECURITY_ATTRIBUTES
  nLength As Long
  lpSecurityDescriptor As Long
  bInheritHandle As Long
End Type

Private Type PROCESS_INFORMATION
  hProcess As Long
  hThread As Long
  dwProcessId As Long
  dwThreadId As Long
End Type

Private Type STARTUPINFO
  cb As Long
  lpReserved As Long
  lpDesktop As Long
  lpTitle As Long
  dwX As Long
  dwY As Long
  dwXSize As Long
  dwYSize As Long
  dwXCountChars As Long
  dwYCountChars As Long
  dwFillAttribute As Long
  dwFlags As Long
  wShowWindow As Integer
  cbReserved2 As Integer
  lpReserved2 As Byte
  hStdInput As Long
  hStdOutput As Long
  hStdError As Long
End Type

Private Type OVERLAPPED
    ternal As Long
    ternalHigh As Long
    offset As Long
    OffsetHigh As Long
    hEvent As Long
End Type

Private Const STARTF_USESHOWWINDOW = &H1
Private Const STARTF_USESTDHANDLES = &H100
Private Const SW_HIDE = 0
Private Const EM_SETSEL = &HB1
Private Const EM_REPLACESEL = &HC2

Private Sub Command1_Click()
  Run
End Sub

Private Sub Run()

  Redirect Text1.Text, Text2
  
  If LCase(Text1) = "net view" Then
    Text2 = Replace(Text2, " ", "")
    Text2 = Mid(Text2, InStr(1, Text2, "\\"), InStr(1, Text2, "Thecommandcompletedsuccessfully.") - InStr(1, Text2, "\\") - 2)
  End If

End Sub

Private Sub Form_Load()
    
    With Text1
      .Left = 120
      .Top = 120
      .Width = 7215
      .BackColor = &H80000006
      .ForeColor = &HFF00&
      .Text = "net view"
    End With
    
    With Text2
      .Left = 120
      .Top = 480
      .Width = 7215
      .BackColor = &H80000006
      .Height = 5895
      .ForeColor = &HFF00&
      .Text = ""
    End With
    
    With Form1
      .BackColor = &H80000006
      .Height = 7035
      .Width = 7470
    End With
     
End Sub

Sub Redirect(cmdLine As String, objTarget As Object)
  Dim i%, t$
  Dim pa As SECURITY_ATTRIBUTES
  Dim pra As SECURITY_ATTRIBUTES
  Dim tra As SECURITY_ATTRIBUTES
  Dim pi As PROCESS_INFORMATION
  Dim sui As STARTUPINFO
  Dim hRead As Long
  Dim hWrite As Long
  Dim bRead As Long
  Dim lpBuffer(1024) As Byte
  pa.nLength = Len(pa)
  pa.lpSecurityDescriptor = 0
  pa.bInheritHandle = True
  
  pra.nLength = Len(pra)
  tra.nLength = Len(tra)

  If CreatePipe(hRead, hWrite, pa, 0) <> 0 Then
    sui.cb = Len(sui)
    GetStartupInfo sui
    sui.hStdOutput = hWrite
    sui.hStdError = hWrite
    sui.dwFlags = STARTF_USESHOWWINDOW Or STARTF_USESTDHANDLES
    sui.wShowWindow = SW_HIDE
    If CreateProcess(vbNullString, cmdLine, pra, tra, True, 0, Null, vbNullString, sui, pi) <> 0 Then
      SetWindowText objTarget.hwnd, ""
      Do
        Erase lpBuffer()
        If ReadFile(hRead, lpBuffer(0), 1023, bRead, ByVal 0&) Then
          SendMessage objTarget.hwnd, EM_SETSEL, -1, 0
          SendMessage objTarget.hwnd, EM_REPLACESEL, False, lpBuffer(0)
          DoEvents
        Else
          CloseHandle pi.hThread
          CloseHandle pi.hProcess
          Exit Do
        End If
        CloseHandle hWrite
      Loop
      CloseHandle hRead
    End If
  End If
End Sub


Private Sub Text1_KeyPress(KeyAscii As Integer)
  If KeyAscii = 13 Then
      Run
  End If
End Sub

Code:
Option Explicit

  Dim IP As String
  Dim Port As String
  Dim TimeOut As Integer
  
Private Sub Command1_Click()

  Scan False
  
End Sub
  
Private Sub Scan(Dalje As Boolean)
  
  If Dalje = True Then
      Dim Prvi As String
      Dim Drugi As String
      
      Prvi = StrReverse(Mid(StrReverse(IP), InStr(1, StrReverse(IP), ".")))
      Drugi = Val(StrReverse(Mid(StrReverse(IP), 1, InStr(1, StrReverse(IP), ".") - 1))) + 1
      
      If Drugi = 256 Then
          Exit Sub
      Else
          IP = Prvi & Drugi
      End If
      
  Else
      IP = txtIPStart
  End If
  
  Port = "445"
  Winsock1.Close
  Debug.Print IP
  Winsock1.Connect IP, Port
  Timer1.Enabled = True
  Timer1.Interval = 1
  
End Sub

Private Sub Timer1_Timer()
  TimeOut = TimeOut + 1
  If TimeOut = 5 Then
      Timer1.Enabled = False
      TimeOut = 0
      Scan True
  End If
End Sub

Private Sub Winsock1_Connect()

  List1.AddItem IP
  Timer1.Enabled = False
  Scan True
  
End Sub