[Excel] Automatsko brisanje redova?

[Excel] Automatsko brisanje redova? 15.11.2006. u 15:53 · pre 243 meseca #1

Interesuje me da li postoji mogucnost za automatsko brisanje praznih redova ili nesto slicno tome sto bi mi bilo kako to olaksalo?
L.M. imam fajl koji sadrzi npr 50.000 redova, a izmedju svakog ima po prazan red. Kako pobrisati prazne redove?

red1: Zapis
red2:
red3: Zapis
red4:
red5: Zapis
red6:
red7:
red8: Zapis
.
.
.
i tako dalje i tako dalje

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 15.11.2006. u 16:00 · pre 243 meseca #2

Evo ti macro za tako nesto:

Code:

Sub BrisiSvakiDrugiRed()
   Dim lngCounter As Long

   For lngCounter = 2 To 25000
      Rows(lngCounter & ":" & lngCounter).Select
      Selection.Delete Shift:=xlUp
   Next

End Sub

Nadam se da znas da iskoristis ovo.

Podrazumeva se da ti je popunjen svaki neparni red (od 1 pa nadalje), a ako nije, pokreni petlju od prvog praznog reda (umesto 2 upisi redni broj prvog praznog reda)

Re: [Excel] Automatsko brisanje redova? 15.11.2006. u 16:20 · pre 243 meseca #3

Ovo je odradilo posao.
Hvala na pomoci

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 11:02 · pre 243 meseca #4

Ovo je naizgled odradilo posao. ali, izgleda da je makro pobrisao neke redove sa podacima koje nije trebalo.
Nije stvar u tome da mi treba da se izbrise svaki drugi red, vec svaki red koji je prazan.
na nekim mestima ima i po dva prazna reda...

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 11:53 · pre 243 meseca #5

Izvini, mislio sam da se radi o brisanju svakog drugog reda, zato se makro zove BrisiSvakiDrugiRed (mislim da si tako i postavio originalno pitanje, u medjuvremenu si ga izmenio, ako se ne varam).

Ako ti treba brisanje praznog reda, onda moras definisati do koje kolone (podesi COLUMN_COUNT) gledamo da li je prazna celija, pa ide malo izmenjen makro:

Code:

Sub BrisiPrazneRedove()
   Dim lngCounter As Long
   Dim lngCounter2 As Long
   Dim cellTMP As Range
   Dim blnEmpty As Boolean

   Const COLUMN_COUNT = 10

   For lngCounter = 1 To 50000

      blnEmpty = True

      For lngCounter2 = 1 To COLUMN_COUNT

         Set cellTMP = Rows(lngCounter & ":" & lngCounter2)

         If (cellTMP.Text & "") <> "" Then

            blnEmpty = False
            Exit For

         End If
      Next

      If blnEmpty Then

         Rows(lngCounter & ":" & lngCounter).Select
         Selection.Delete Shift:=xlUp
         lngCounter = lngCounter + 1

      End If

   Next

End Sub

Nisam bas stigao da istestiram, ali javi ako nesto nije u redu.

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 12:45 · pre 243 meseca #6

Opet brise neke stvari sto ne treba. takodje popuni dva reda pa ostavi dva prazna i sve tako
Otprilike ovako izgleda tabela.

red01: |123456|#####|#####|#####|#####|#####|#####|#####|
red02: |#####|#####|#####|#####|#####|#####|#####|#####|
red03: |#####|#####|#####|#####|#####|Datum |#####|nesto |
red04: |#####|#####|#####|#####|#####|#####|#####|#####|
red05: |#####|#####|#####|#####|#####|Datum |#####|nesto |
red06: |#####|#####|#####|#####|#####|#####|#####|#####|
red07: |456987|#####|nesto |datum |#####|#####|#####|cena |
red08: |#####|#####|#####|#####|#####|#####|#####|#####|
red09: |123456|#####|nesto |datum |#####|#####|#####|#####
red10: |#####|#####|#####|#####|#####|#####|#####|cena |
red11: |#####|#####|#####|#####|#####|#####|#####|#####|
red12: |987654|#####|#####|#####|#####|#####|#####|#####|

...i tako dalje...

# su prazne celije (one ne treba da se brisu, samo prazni redovi). uvek mi obrise nesto sto ne treba.
Izvini ako te smaram, ali mi je ovo mnogo potrebno. Ako ti nije problem u kodu koji mi saljes naznaci mi ako treba nesto ja da ubacim, posto sam slab sa macroima

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 13:31 · pre 243 meseca #7

Kao sto sam i rekao:

Citat:

goranvuc:
Nisam bas stigao da istestiram, ali javi ako nesto nije u redu.

A evo i ispravljene procedure:

Code:

Sub BrisiPrazneRedove()
   Dim lngCounter As Long
   Dim lngCounter2 As Long
   Dim cellTMP As Range
   Dim blnEmpty As Boolean
   Dim lngRowsDeleted As Long

   Const COLUMN_COUNT = 10
   Const ROW_COUNT = 50000

   lngRowsDeleted = 0

   For lngCounter = 1 To ROW_COUNT

      blnEmpty = True

      For lngCounter2 = 1 To COLUMN_COUNT

         Set cellTMP = Cells((lngCounter - lngRowsDeleted), lngCounter2)

         If (cellTMP.Text & "") <> "" Then

            blnEmpty = False
            Exit For

         End If
      Next

      If blnEmpty Then

         Rows((lngCounter - lngRowsDeleted) & ":" & (lngCounter - lngRowsDeleted)).Select
         Selection.Delete Shift:=xlUp
         lngRowsDeleted = lngRowsDeleted + 1

      End If

   Next

End Sub

Javi ako opet nesto nije u redu.

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 14:07 · pre 243 meseca #8

Brisanje praznih redova je uspelo.
Sad je problem, koliko sam primetio, svaka celija koja je formatirana Fromat Cells... -> Border je izbrisana.
npr. imam:

|Account subtotals |#########|########|#######|
|################| #########|########|12345.00 |-- formatirano
|Account Net Change |15/11/2006 |########|######|
|################| #########|########|1500.00 |-- formatirano
|Account Ending Balance|15/11/2006 |########|1500.00 |-- formatirano

nadam se da si me razumeo sta hocu da kazem...

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 14:14 · pre 243 meseca #9

Nema veze formatiranje, mozda su ti te celije u kolonama vecim od 10-te, a ako je to promeni COLUMN_COUNT konstantu (ona sluzi za redni broj zadnje kolone u kojoj imas "nesto")

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 14:42 · pre 243 meseca #10

ok. ovo je odradjeno odlicno. imam jos par stvari da te pitam koje predpostavljam da se rade pomocu makroa
tabela:

A B C D E F
|1.Broj|######|######|######|######|######|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|2.Broj|######|######|######|######|######|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|
|####|######|######|datum##|broj###|nesto###|

...i tako dalje
potrebna mi je automatizacija koja ce da kopira 1.Broj u kolonu "A" sve dok ne stigne do 2.Broj. Tada pocinje da kopira 2.Broj dalje do 3.Broj i td. i tako dok ne stigne do kraja

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 14:44 · pre 243 meseca #11

A sta ti je izmedju 1 i 2, prazno?

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 14:48 · pre 243 meseca #12

da da

|1.Broj |######|######|######|######|######|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|2.Broj |######|######|######|######|######|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|
|prazno|######|######|datum##|broj###|nesto###|

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 15:13 · pre 243 meseca #13

samo da dopunim
1.Broj nije broj nego gledaj na to kao zapis
isto tako 2.Broj
kasnije ce od toga biti broj. sada je tu
Racun: 1234-567-890

Potpis

Use the SEARCH, Luke!

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 15:20 · pre 243 meseca #14

Evo:

Code:

Sub PopuniPraznine()
   Dim cellTMP As Range
   Dim cellCurr As Range
   Dim lngCounter As Long

   Const CURR_COL = 1
   Const END_ROW = 50000

   For lngCounter = 1 To END_ROW

      Set cellTMP = Cells(lngCounter, CURR_COL)

      If (Cells(lngCounter + 1, CURR_COL).Text & "") = "" Then

         lngCounter = lngCounter + 1

         Do While (Cells(lngCounter, CURR_COL).Text & "") = ""

            Set cellCurr = Cells(lngCounter, CURR_COL)
            cellCurr.Value = cellTMP.Text

            If lngCounter = END_ROW Then

               lngCounter = lngCounter + 1
               Exit Do

            End If

            lngCounter = lngCounter + 1

         Loop

         lngCounter = lngCounter - 1

      End If

   Next

End Sub

Makro radi za CURR_COL kolonu (u ovom primeru je to kolona 1) i za END_ROW redova (50000).

Imas jos nesto?

P.S.

Na koga da pravim fakturu?

Re: [Excel] Automatsko brisanje redova? 16.11.2006. u 15:59 · pre 243 meseca #15

Sredio sam tabelu

Hvala ti puno na pomoci!!!
Pozdrav...

Potpis

Use the SEARCH, Luke!

Forum kao aplikacija na telefonu

Srodne teme