[es] - Problem sa winsock-om

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net

+44 Profil

Re: Problem sa winsock-om

^{29.07.2008. u 18:46 - pre 191 meseci}

ne mora da bude ocx unutar system32 foldera, tj ukoliko je custom dll/ocx onda je pozeljnije drzati ga uz aplikaciju a ne trpati sve u sistemski folder (mada je u ovom slucaju bolja solucija kopirati u system32)

da ne bi pokretali command promt (posto ima onih programera koji iz ne znam kojih razloga ne vole da koriste konzolu) mozete napraviti ovakav .vbs fajl:

Code:

Dim FSO
Dim RegShell
Dim regsvr
Dim answer1
Dim answer2

answer1 = MsgBox("This script will add Register and Unregister" & vbCrLf & _
                "options to right-click menu on *.dll and *.ocx files" & vbCrLf & _
                "allowing you to just double-click *.dll or *.ocx file" & vbCrLf & _
                "to register it!" & vbCrLf & vbCrLf & _
                "Click 'Yes' to continue." & vbCrLf & _
                "If you want to remove this feature click 'No'." & vbCrLf & _
                "Click 'Cancel' to leave settings unchanged.", _
                vbYesNoCancel + vbQuestion, "DLL & OCX reg-unreg")

answer2 = MsgBox("Do you want to display *.dll and *.ocx files as icons in explorer?", _
                vbYesNoCancel + vbQuestion, "DefaultIcons")

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
Set RegShell = WScript.CreateObject("WScript.Shell")

regsvr = Replace(FSO.getSpecialFolder(1) & "\RegSvr32.exe", "\\", "\")

If answer1 = vbYes Then
    If FSO.FileExists(regsvr) = False Then
        Call MsgBox("RegSvr32.exe file not found!" & vbCrLF & _
                    "Cannot continue setup.", vbOKOnly + vbCritical, "Error")
    Else
        Dim cmdReg
        Dim cmdUnreg

        cmdReg = Chr(34) & regsvr & Chr(34) & " " & Chr(34) & "%1" & Chr(34)
        cmdUnreg = Chr(34) & regsvr & Chr(34) & " /u " & Chr(34) & "%1" & Chr(34)

        Call RegShell.RegWrite("HKCR\dllfile\shell\open\", "Register")
        Call RegShell.RegWrite("HKCR\dllfile\shell\open\command\", cmdReg)
        Call RegShell.RegWrite("HKCR\dllfile\shell\unreg\", "Unregister")
        Call RegShell.RegWrite("HKCR\dllfile\shell\unreg\command\", cmdUnreg)
        Call RegShell.RegWrite("HKCR\ocxfile\shell\open\", "Register")
        Call RegShell.RegWrite("HKCR\ocxfile\shell\open\command\", cmdReg)
        Call RegShell.RegWrite("HKCR\ocxfile\shell\unreg\", "Unregister")
        Call RegShell.RegWrite("HKCR\ocxfile\shell\unreg\command\", cmdUnreg)

    End If
Else
    If answer1 = vbNo Then
        Call RegShell.RegDelete("HKCR\dllfile\shell\open\")
        Call RegShell.RegDelete("HKCR\dllfile\shell\unreg\")
        Call RegShell.RegDelete("HKCR\ocxfile\shell\open\")
        Call RegShell.RegDelete("HKCR\ocxfile\shell\unreg\")
    End If
End If

If answer2 = vbYes Then
    Call RegShell.RegWrite("HKCR\dllfile\DefaultIcon\", "%1")
    Call RegShell.RegWrite("HKCR\ocxfile\DefaultIcon\", "%1")
Else
    If answer2 = vbNo Then
        Call RegShell.RegWrite("HKCR\dllfile\DefaultIcon\", "")
        Call RegShell.RegWrite("HKCR\ocxfile\DefaultIcon\", "")
    End If
End If

i pokrenuti ga (dupli-klik).. ovo sam davno napisao bas zbog jednog takvog programera koji ne voli rad u konzoli...

rafforum.rs - Forum Računarskog Fakulteta

Odgovor na temu

dava
Banja Luka

Član broj: 27208
Poruke: 893

+384 Profil

Re: Problem sa winsock-om

^{29.07.2008. u 21:43 - pre 191 meseci}

Citat:

ne mora da bude ocx unutar system32 foldera, tj ukoliko je custom dll/ocx onda je pozeljnije drzati ga uz aplikaciju a ne trpati sve u sistemski folder

Nigdje ja nisam rekao da mora biti u system32 ali je po meni to bolje rjesenje. Ako drzis u folderu gdje je program uvijek postoji opasnost na taj folder prekopiras na neko drugo mjesto ili ga jednostavno preimenujes i path je izgubljen. ;)

Mogao si to izvesti i sa batch fajlom sljedeceg sadrzaja (koji je naravno na istoj putanji gdje i .ocx):

Code:

regsvr32 imeKontrole.ocx /s
regsvr32 imeKontrole2.ocx /s
regsvr32 imeKontrole3.ocx /s

SELECT * FROM หน่วยงานหลัก WHERE ยสันติ LIKE 'โดย%'

Odgovor na temu

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net

+44 Profil

Re: Problem sa winsock-om

^{29.07.2008. u 22:20 - pre 191 meseci}

ja sam mislio na situaciju kada radis instalaciju programa, jedan od razloga zasto postoji dll hell je sto vecina programera misli da je najbolje smestiti dll u sistemski folder pa nema veze ako je neka druga aplikacija predhodno instalirala u isti taj sistemski folder dll fajl istog imena ali novije verzije...

a sto se tice ovoga sa batch fajlom, to je ok pristup ali ako pokrenes onu skriptu (nema veze odakle je pokreces), sto je dovoljno samo jednom da uradis, dobices dve nove komande "Register" i "Unregister" u context meniju windows explorera za sve fajlove sa ekstenzijom dll i ocx. tako da mozes duplim klikom da registrujes dll/ocx fajl a desnim klikom i odabirom opcije "Unregister" da unregistrujes. bar ja koristim ovaj pristup, nekako mi je elegantnije resenje nego da pisem batch fajl svaki put...

rafforum.rs - Forum Računarskog Fakulteta

Odgovor na temu