automatsko ponunjavanje tabele - kartica robe

Code:

Public Sub Knjizi_Rep(Broj_ulaza As Long)
     Dim Baza              As Database
     Dim Sl_Zagl           As Recordset
     Dim Usl_Zagl          As String
     Dim Sl_Stavke         As Recordset
     Dim Usl_Stavke        As String
     Dim Sl_Repromat       As Recordset
     Dim Sl_Matrep         As Recordset
     Dim Usl_Matrep        As String
     Dim zadnji            As Long
     Dim udatum            As Date
     Dim udokument         As String
     Dim usifpart          As Long
     Dim ubrulaz           As Long
     Dim uvaluta           As Date
     Dim vrsta             As String
     Dim usifrau           As Long
     Dim uprosec           As Currency
     Dim suma              As Currency
     
     suma = 0
     uprosec = 0
     
     Usl_Zagl = "SELECT * FROM [Prijemnica] WHERE ((([Prijemnica].BrojPrijemnice)= " & Broj_ulaza & "));"
     Usl_Stavke = "SELECT * FROM [PrijemnicaStavka] WHERE ((([PrijemnicaStavka].BrojPrijemnice)= " & Broj_ulaza & "));"

     Set Baza = CurrentDb()
     Set Sl_Zagl = Baza.OpenRecordset(Usl_Zagl, dbOpenDynaset)
     Set Sl_Stavke = Baza.OpenRecordset(Usl_Stavke, dbOpenDynaset)
     Set Sl_Repromat = Baza.OpenRecordset("PROMETREPROMATERJALA", dbOpenDynaset)
     
    If Sl_Zagl.RecordCount > 0 Then
        Sl_Zagl.MoveFirst   'otidi na prvi slog Zaglavlja
        ubrulaz = Sl_Zagl![BrojPrijemnice]
        udatum = Sl_Zagl![DatumPrijema]
        udokument = Sl_Zagl![NaOsnovu]
        usifpart = Sl_Zagl![SifraPartnera]
        uvaluta = Sl_Zagl![ValutaPlacanja]
        If Sl_Zagl![IndikatorKnjizenja] = 1 Then  'ako je dokument vec proknjizen
            MsgBox "Ovaj dokument je vec proknjizen!", vbCritical, "Paznja"
            GoTo Kraj
        End If
    Else
        MsgBox "Nema podataka", vbInformation, "Obavestenje"
        GoTo Kraj
    End If
    If MsgBox("Potvrdite knjizenje ?", vbYesNo, "Paznja") = vbNo Then
       Exit Sub
    End If
    If Sl_Stavke.RecordCount > 0 Then
       Sl_Stavke.MoveFirst
       While Not Sl_Stavke.EOF
          ' dodaje slogove u tabelu prometrepromaterjala
          With Sl_Repromat
              .AddNew
              ![BrojPrijemnice] = Sl_Stavke![BrojPrijemnice]
              ![DatumPrometa] = udatum
              ![NaOsnovu] = udokument
              ![SifraPartnera] = usifpart
              ![ValutaPlacanja] = uvaluta
              ![SifraUlaza] = Sl_Stavke![SifraUlaza]
              ![Kolicina] = Sl_Stavke![Kolicina]
              ![CENA] = Sl_Stavke![CENA]
              ![ZavisniTroskovi] = Sl_Stavke![FiksniTroskovi]
              ![Ulaz_Izlaz] = "U"
              .Update
          End With
          usifrau = Sl_Stavke![SifraUlaza]
          Usl_Matrep = "SELECT * FROM [MagacinRepromaterjala] WHERE ((([MagacinRepromaterjala].SifraUlaza) = " & usifrau & "));"
          Set Sl_Matrep = Baza.OpenRecordset(Usl_Matrep, dbOpenDynaset)
          If Sl_Matrep.RecordCount > 0 Then
             Sl_Matrep.MoveFirst
             ' azurira prosecnu cenu
             If (Sl_Matrep![Kolicina] + Sl_Stavke![Kolicina]) > 0 Then
                uprosec = ((Sl_Matrep![ProsecnaCena] * Sl_Matrep![Kolicina]) _
                + (Sl_Stavke![CENA] * Sl_Stavke![Kolicina])) _
                / (Sl_Matrep![Kolicina] + Sl_Stavke![Kolicina])
             End If
             uprosec = Round(uprosec, 2)
             ' povecava kolicinu u tabeli magacinrepromaterjala
             With Sl_Matrep
                 .Edit
                 ![Kolicina] = Sl_Matrep![Kolicina] + Sl_Stavke![Kolicina]
                 ![ProsecnaCena] = uprosec
                 .Update
             End With
          Else
             ' dodaje novu stavku u MAGACINREPROMATERJALA
             With Sl_Matrep
                 .AddNew
                 ![SifraUlaza] = Sl_Stavke![SifraUlaza]
                 ![NazivUlaza] = Sl_Stavke![NazivUlaza]
                 ![Jm] = Sl_Stavke![Jm]
                 ![Kolicina] = Sl_Stavke![Kolicina]
                 ![ProsecnaCena] = Sl_Stavke![CENA]
                 .Update
             End With
          End If
          suma = suma + Round(Sl_Stavke![Kolicina] * Sl_Stavke![CENA], 2)
          Sl_Stavke.MoveNext
       Wend
    End If
    With Sl_Zagl
         .Edit
         ![IndikatorKnjizenja] = 1   'obelezava u zaglavlju repromaterjala da je proknjizeno
         .Update
    End With
    ' poruka da je proknjizeno
    MsgBox "Prijemnica je proknjizena", vbInformation, "Obavestenje"
    
Kraj:

    Set Baza = Nothing
    
End Sub