[es] - ComboBox problem

LinburG
Podgorica

Član broj: 66623
Poruke: 12
*.crnagora.net.

Profil

^{05.11.2005. u 22:03 - pre 224 meseci}

Zna li neko kako da napravim da mi se comboBox ponasa tako da kad pocnem da kucam u njmu neki naziv vuce iz baze preostali dio teksta naziva. Recimo kucam ime klijenta i ako ukucam "Dra" on mi izbaca "Dragan" stim sto je "gan" markirano a ako na "Dra" dodam jos "s" on ce izbaciti "Drasko" naravno "ko" je markirano. Sto znaci da cu kad mi bude odgovaralo ono sto je on dodao na tekst koji sam ja napisao pritiskom entera odraditi nesto nije bitno sad sto. Podrazumjeva se da su i "Dragan" i "Drasko" imena klijenata u tabeli klijenti. Radim sa access bazom.

_{[Ovu poruku je menjao LinburG dana 05.11.2005. u 23:04 GMT+1]}

Odgovor na temu

ivan74
Beogad

Član broj: 59230
Poruke: 80
212.200.146.*

Profil

Re: ComboBox problem

^{08.11.2005. u 09:29 - pre 224 meseci}

konkretno:

Code:

   Private Sub cmbMunicipality_Leave(ByVal sender As Object, ByVal e As System.EventArgs) Handles cmbMunicipality.Leave

        Dim Selektovanindex As Integer
        'pronalazi tacan string
        Selektovanindex = cmbMunicipality.FindStringExact(cmbMunicipality.Text)
        'ako je korisnik uneo glupost pozicioniraj se na prvu opstinu
        If Selektovanindex < 0 Then
            cmbMunicipality.SelectedIndex = 0
        Else
            cmbMunicipality.SelectedIndex = Selektovanindex
        End If
    End Sub

    '-----------------
    Private Sub cmbMunicipality_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles cmbMunicipality.KeyUp

        Dim Selektovanindex As Integer
        Dim Item As Object
        Dim Pronadjeno, Otkucano, Dodato As String

        'kursorski tasteri
        Select Case e.KeyCode
            Case Keys.Back, Keys.Left, Keys.Right, Keys.Up, Keys.Delete, Keys.Down
                Return
        End Select

        Otkucano = cmbMunicipality.Text
        'pronalazi prvo pojavljivanje stringa koji pocinje sa oktucano
        Selektovanindex = cmbMunicipality.FindString(Otkucano)

        If Selektovanindex >= 0 Then
            Item = cmbMunicipality.Items(Selektovanindex)
            Pronadjeno = cmbMunicipality.GetItemText(Item)

            Dodato = Pronadjeno.Substring(Otkucano.Length)
            cmbMunicipality.Text = Otkucano & Dodato

            cmbMunicipality.SelectionStart = Otkucano.Length
            cmbMunicipality.SelectionLength = Dodato.Length
        Else
            'ako je prvo slovo neko na koje nista ne pocinje postavi ga na ""
            If cmbMunicipality.Text.Length = 1 Then
                cmbMunicipality.Text = ""
            End If
        End If
    End Sub

Pretpostavlja se da je combo vec povezan na izvorom podataka.
Ovo sam koristio za combo u kome se nalaze nazivi opstina, radi sasvim fino.

Odgovor na temu