Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.

VB kod za eject cd?

[es] :: Visual Basic 6 :: VB kod za eject cd?

[ Pregleda: 6107 | Odgovora: 16 ] > FB > Twit

Postavi temu Odgovori

Autor

Pretraga teme: Traži
Markiranje Štampanje RSS

Toxic Flame
Aljosha Sologub
Beograd

Član broj: 32704
Poruke: 288
*.etf.bg.ac.yu.



+1 Profil

icon VB kod za eject cd?03.11.2004. u 09:18 - pre 236 meseci
moze li mi neko reci kod kojim se otvaraju vratanca cd odnosno kojim se cd ejectuje?
potreban mi je VB kod
_-=amateur=-_
 
Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.htnet.hr.



+8 Profil

icon Re: VB kod za eject cd?03.11.2004. u 09:27 - pre 236 meseci
Evo ti ovaj način:


Code:

Private Declare Function mciSendString Lib "winmm.dll" Alias _ 
"mciSendStringA" (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, _
 ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long

Private Sub Command1_Click()
On Error Resume Next
retvalue = mciSendString("set CDAudio door open", returnstring, 127, 0)
End Sub

Private Sub Command2_Click()
On Error Resume Next
retvalue = mciSendString("set CDAudio door closed", returnstring, 127, 0)
End Sub


[Ovu poruku je menjao VRKY dana 03.11.2004. u 13:04 GMT+1]
 
Odgovor na temu

mladenovicz
Zeljko Mladenovic
Xoran Technologies, Inc., Ann Arbor, MI,
USA / Software Engineer
Ann Arbor, MI, USA

Član broj: 6598
Poruke: 2065
*.bg.wifi.vline.verat.net.

Jabber: mladenovicz@elitesecurity.org
ICQ: 95144142
Sajt: yubc.net/~mz


Profil

icon Re: VB kod za eject cd?03.11.2004. u 09:40 - pre 236 meseci
Code:

'Example by Howard Henry Schlunder
' This example requires one command button (Command1)
Private Declare Function GetVersion Lib "kernel32" () As Long
Private Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" _
(ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, _
lpSecurityAttributes As Any, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, _
ByVal hTemplateFile As Long) As Long
Private Declare Function DeviceIoControl Lib "kernel32" (ByVal hDevice As Long, _
ByVal dwIoControlCode As Long, lpInBuffer As Any, ByVal nInBufferSize As Long, lpOutBuffer As Any, _
ByVal nOutBufferSize As Long, lpBytesReturned As Long, lpOverlapped As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Const INVALID_HANDLE_VALUE = -1
Private Const OPEN_EXISTING = 3
Private Const FILE_FLAG_DELETE_ON_CLOSE = 67108864
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const IOCTL_STORAGE_EJECT_MEDIA = 2967560
Private Const VWIN32_DIOC_DOS_IOCTL = 1
 
Private Type DIOC_REGISTERS
  reg_EBX As Long
  reg_EDX As Long
  reg_ECX As Long
  reg_EAX As Long
  reg_EDI As Long
  reg_ESI As Long
  reg_Flags As Long
End Type
 
Private Sub Command1_Click()
Dim hDrive As Long, DummyReturnedBytes As Long
Dim EjectDrive As String, DriveLetterAndColon As String
Dim RawStuff As DIOC_REGISTERS
  EjectDrive = InputBox("Which drive shall we try to eject the media from?", "Eject Media")
  If Len(EjectDrive) Then 'Confirm the user didn't cancel
    DriveLetterAndColon = UCase(Left$(EjectDrive & ":", 2)) 'Make it all caps for easy interpretation
    If GetVersion >= 0 Then 'We are running Windows NT/2000
      hDrive = CreateFile("\\.\" & DriveLetterAndColon, GENERIC_READ Or GENERIC_WRITE, 0, ByVal 0, OPEN_EXISTING, 0, 0)
      If hDrive <> INVALID_HANDLE_VALUE Then
        'Eject media!
        Call DeviceIoControl(hDrive, IOCTL_STORAGE_EJECT_MEDIA, 0, 0, 0, 0, DummyReturnedBytes, ByVal 0)
        Call CloseHandle(hDrive)  'Clean up after ourselves
      End If
    Else  'We are running Win9x/Me
      hDrive = CreateFile("\\.\VWIN32", 0, 0, ByVal 0, 0, FILE_FLAG_DELETE_ON_CLOSE, 0)
      If hDrive <> INVALID_HANDLE_VALUE Then
        'Setup our raw registers to use Interrupt 21h Function 440Dh Minor Code 49h
        RawStuff.reg_EAX = &H440D   'The function to use
        RawStuff.reg_EBX = Asc(DriveLetterAndColon) - Asc("A") + 1 'The drive to do it on
        RawStuff.reg_ECX = &H49 Or &H800    
        'The minor code of the function in the low byte of the low word and the device category of 8 in the high byte of the low word
        'Eject media!
        Call DeviceIoControl(hDrive, VWIN32_DIOC_DOS_IOCTL, RawStuff, LenB(RawStuff), RawStuff, LenB(RawStuff), DummyReturnedBytes, ByVal 0)
        Call CloseHandle(hDrive)  'Clean up after ourselves
      End If
    End If
  End If
End Sub


 
Odgovor na temu

Toxic Flame
Aljosha Sologub
Beograd

Član broj: 32704
Poruke: 288
*.etf.bg.ac.yu.



+1 Profil

icon Re: VB kod za eject cd?03.11.2004. u 09:47 - pre 236 meseci
ovo radi!
Hvala...
_-=amateur=-_
 
Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.htnet.hr.



+8 Profil

icon Re: VB kod za eject cd?03.11.2004. u 10:01 - pre 236 meseci
A što onaj moj kod ne radi? Možda ne radi zbog deklaracije jer sam ju razlamao da stane...
 
Odgovor na temu

mladenovicz
Zeljko Mladenovic
Xoran Technologies, Inc., Ann Arbor, MI,
USA / Software Engineer
Ann Arbor, MI, USA

Član broj: 6598
Poruke: 2065
*.bg.wifi.vline.verat.net.

Jabber: mladenovicz@elitesecurity.org
ICQ: 95144142
Sajt: yubc.net/~mz


Profil

icon Re: VB kod za eject cd?03.11.2004. u 10:23 - pre 236 meseci
Kada stavljas _ moras da stavis jedan space pre.
 
Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.htnet.hr.



+8 Profil

icon Re: VB kod za eject cd?03.11.2004. u 12:05 - pre 236 meseci
OK, izmjenjeno, sad bi onda trebalo šljakati...
 
Odgovor na temu

Toxic Flame
Aljosha Sologub
Beograd

Član broj: 32704
Poruke: 288
*.etf.bg.ac.yu.



+1 Profil

icon Re: VB kod za eject cd?11.11.2004. u 10:50 - pre 235 meseci
VRKY sto se tice tvog koda... on radi kod mene ali kada sam ga hteo poslati.... pali mi se antivirus koji kaze da je potencionaly unsafe...
postoji li kod koji to nece da pali av?
_-=amateur=-_
 
Odgovor na temu

goran Ivcic
Hr

Član broj: 7178
Poruke: 70
*.cmu.carnet.hr.



Profil

icon Re: VB kod za eject cd?23.01.2005. u 20:40 - pre 233 meseci
Mozda jos jedno malo pitanjce...

Ovaj prvi kod radi kada ga pokrenem iz VB6,
ali kada pokusam i napravim .exe tada ne radi!

Zasto?????
Gogy
 
Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.t-com.hr.



+8 Profil

icon Re: VB kod za eject cd?23.01.2005. u 20:58 - pre 233 meseci
Koji? Moj kod ili?
 
Odgovor na temu

goran Ivcic
Hr

Član broj: 7178
Poruke: 70
*.cmu.carnet.hr.



Profil

icon Re: VB kod za eject cd?28.01.2005. u 18:39 - pre 233 meseci
Da, da, tvoj. Ne znam zasto???
Gogy
 
Odgovor na temu

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net


+44 Profil

icon Re: VB kod za eject cd?28.01.2005. u 19:58 - pre 233 meseci
evo ovaj zeljkov kod radi i moze da se kompiluje, vrkyjev nisam probao mada sam tako nesto video na psc (i radilo je)...
 
Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.t-com.hr.



+8 Profil

icon Re: VB kod za eject cd?28.01.2005. u 21:38 - pre 233 meseci
Evo, ponovno pokušavam i radi... zašto kod tebe ne? Piše li kaki error
 
Odgovor na temu

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net


+44 Profil

icon Re: VB kod za eject cd?29.01.2005. u 13:16 - pre 233 meseci
meni radi vrkijev kod, ne znam zasto nece kod tebe, pokusaj ovako:
Code:

Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
(ByVal lpstrCommand As String, ByVal lpstrReturnString As String, _
ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long

Public Sub CDRom(onoff As Boolean)
    Dim lReturn As Long
    Dim state As String
    
    If onoff Then state = " open" Else state = " close"
    
    mciSendString "set CDAudio door" & state, lReturn, 127, 0

End Sub


bacis ovo u modul i samo negde u kodu dodas CDRom True/False
meni radi
 
Odgovor na temu

PeecO Undead
PeecO Undead
Prnjavor

Član broj: 93956
Poruke: 2
*.dialup.blic.net.



Profil

icon Re: VB kod za eject cd?05.06.2006. u 00:37 - pre 216 meseci
ma samo napravi dva buttona i modul

U form:

Code:
Private Sub Command1_Click()
lngReturn = mciSendString("set CDAudio door open", strReturn, 127, 0)
End Sub

Private Sub Command2_Click()
lngReturn = mciSendString("set CDAudio door closed", strReturn, 127, 0)
End Sub


U Modul:

Code:
Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long


[Ovu poruku je menjao Shadowed dana 05.06.2006. u 15:11 GMT+1]
PeecO Undead cooler...
 
Odgovor na temu

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net


+44 Profil

icon Re: VB kod za eject cd?05.06.2006. u 10:36 - pre 216 meseci
@PeecO Undead: pogledaj timestamp-ove :)
 
Odgovor na temu

Nibble

Član broj: 63173
Poruke: 302
*.dlp484.bih.net.ba.



+1 Profil

icon Re: VB kod za eject cd?05.06.2006. u 14:04 - pre 216 meseci
Sta ima veze nekom ce zatrebati :))
 
Odgovor na temu

[es] :: Visual Basic 6 :: VB kod za eject cd?

[ Pregleda: 6107 | Odgovora: 16 ] > FB > Twit

Postavi temu Odgovori

Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.