[es] - Dva laksa pitanja vezana za Windows-ov folder

JordaMelior
Jorda Melior

Član broj: 27174
Poruke: 24
*.teol.net

Profil

Dva laksa pitanja vezana za Windows-ov folder

^{24.08.2004. u 18:13 - pre 239 meseci}

Zanima me kako VB aplikacija moze da prepozna Windows-ov folder i u njega smesta file-ove, kopira iz njega itd...
Recimo da je korisnik promenio i particiju i naziv foldera kad je instalirao Windows, kako u tom slucaju aplikacija pronalazi windows-ov folder i kako bi bio kod za jednostavan primer: Kopirati file C:\test.txt u windows-ov direktorijum.
Kako aplikacija da prepozna o kojoj verziji windowsa je rec i da u slucaju da je npr. win2000 uradi sledece, a ako je winXP onda nesto drugo?
Unapred hvala!

PS: Code kod kopiranja fileova, ako moze, bez FSO-a... dakle onaj obicni

Code:
FileCopy "C:\test.txt", "i sta onda:)"

Jason Newsted rulazzzzzz!

Odgovor na temu

Shadowed
Vojvodina

Član broj: 649
Poruke: 12851

+4784 Profil

Re: Dva laksa pitanja vezana za Windows-ov folder

^{24.08.2004. u 19:41 - pre 239 meseci}

http://www.elitesecurity.org/tema/51341

Nebojsa Milanovic: Što se tiče Trumpa, smatram ga vrhunskim predsednikom i voleo bih da živim u državi na čijem je on čelu.
Nebojsa Milanovic: Rusija ne laže, ne vodi osvajačke ratove
Nebojsa Milanovic: Trump je svetla tačka u USA blatu.

Odgovor na temu

VRKY

Član broj: 21087
Poruke: 4690
*.net.htnet.hr

+8 Profil

Re: Dva laksa pitanja vezana za Windows-ov folder

^{24.08.2004. u 22:22 - pre 239 meseci}

Stavi ovo u Moduel:

Code:

Public Const max_path = 260
Public Declare Function GetWindowsDirectory Lib "kernel32" Alias "GetWindowsDirectoryA" (ByVal lpbuffer As String, ByVal nsize As Long) As Long
Public Function WinDir_func() As String
  Dim lpbuffer As String
  Dim windir As String
  lpbuffer = Space$(max_path)
  WinDir_func = Left$(lpbuffer, GetWindowsDirectory(lpbuffer, max_path)) ' save default windows path in this variable :)
End Function

I ovo u formu (primjer je za kopiranje fajlova):

Code:

windir = WinDir_func
FileCopy App.Path + "\" + App.EXEName + ".exe", windir & "\ProBa" & ".exe"

Odgovor na temu

JordaMelior
Jorda Melior

Član broj: 27174
Poruke: 24
*.teol.net

Profil

Re: Dva laksa pitanja vezana za Windows-ov folder

^{25.08.2004. u 16:56 - pre 239 meseci}

OK, ovo sve sooper radi, HVALA!
Ipak, cini mi se da nisam dobio odgovor na pitanje kako da aplikacija prepozna verziju OS Windows (da li je 98/ME/2K/XP...) te da razlicite radnje (npr. razlicite MsgBox-ove ispisuje za svaki).
Jel postoji neki drugi nacin osim da proveravam da li postoji file karakteristican za svaki od ovih OS-a?

Jason Newsted rulazzzzzz!

Odgovor na temu

Aleksandar Ružičić
Software Architect, Appricot d.o.o.
Beograd

Član broj: 26939
Poruke: 2881

Jabber: krckoorascic@gmail.com
Sajt: krcko.net

+44 Profil

Re: Dva laksa pitanja vezana za Windows-ov folder

^{25.08.2004. u 16:59 - pre 239 meseci}

Evo ovo ti je iz API-Guida

Code:

'Example submitted by zeloran stronghold ([email protected])
'Visit his homepage at www.mosucker.de or www.mosucker.de.vu
'This example needs a form and a module.
'On the form, their should be two Labels (lbl_operatingplatform
'and lbl_operatingsystem)
'IN A FORM:
Private Sub Form_Load()
    Select Case OperatingPlatform
        Case Enum_OperatingPlatform.Platform_Windows_32: lbl_operatingplatform.Caption = "Windows 32"
        Case Enum_OperatingPlatform.Platform_Windows_95_98_ME: lbl_operatingplatform.Caption = "Windows 95/98/ME"
        Case Enum_OperatingPlatform.Platform_Windows_NT_2K_XP: lbl_operatingplatform.Caption = "Windows NT/2K"
    End Select
    Select Case OperatingSystem
        Case System_Windows_32: lbl_operatingsystem.Caption = "Windows 32"
        Case System_Windows_95: lbl_operatingsystem.Caption = "Windows 95"
        Case System_Windows_98: lbl_operatingsystem.Caption = "Windows 98"
        Case System_Windows_ME: lbl_operatingsystem.Caption = "Windows ME"
        Case System_Windows_NT: lbl_operatingsystem.Caption = "Windows NT"
        Case System_Windows_2K: lbl_operatingsystem.Caption = "Windows 2K"
        Case System_Windows_XP: lbl_operatingsystem.Caption = "Windows XP"
    End Select
End Sub
'IN A MODULE:
Private Declare Function GetVersionExA Lib "kernel32" (lpVersionInformation As OSVERSIONINFO) As Long
Private Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Public Enum Enum_OperatingPlatform
  Platform_Windows_32 = 0
  Platform_Windows_95_98_ME = 1
  Platform_Windows_NT_2K_XP = 2
End Enum
Public Enum Enum_OperatingSystem
  System_Windows_32 = 0
  System_Windows_95 = 1
  System_Windows_98 = 2
  System_Windows_ME = 3
  System_Windows_NT = 4
  System_Windows_2K = 5
  System_Windows_XP = 6
End Enum
Public Function OperatingPlatform() As Enum_OperatingPlatform
    Dim lpVersionInformation As OSVERSIONINFO
    lpVersionInformation.dwOSVersionInfoSize = Len(lpVersionInformation)
    Call GetVersionExA(lpVersionInformation)
    OperatingPlatform = lpVersionInformation.dwPlatformId
End Function
Public Function OperatingSystem() As Enum_OperatingSystem
    Dim lpVersionInformation As OSVERSIONINFO
    lpVersionInformation.dwOSVersionInfoSize = Len(lpVersionInformation)
    Call GetVersionExA(lpVersionInformation)
    If (lpVersionInformation.dwPlatformId = Platform_Windows_32) Then
        OperatingSystem = System_Windows_32
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_95_98_ME) And (lpVersionInformation.dwMinorVersion = 0) Then
        OperatingSystem = System_Windows_95
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_95_98_ME) And (lpVersionInformation.dwMinorVersion = 10) Then
        OperatingSystem = System_Windows_98
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_95_98_ME) And (lpVersionInformation.dwMinorVersion = 90) Then
        OperatingSystem = System_Windows_ME
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_NT_2K_XP) And (lpVersionInformation.dwMajorVersion < 5) Then
        OperatingSystem = System_Windows_NT
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_NT_2K_XP) And (lpVersionInformation.dwMajorVersion = 5) And (lpVersionInformation.dwMinorVersion = 0) Then
        OperatingSystem = System_Windows_2K
    ElseIf (lpVersionInformation.dwPlatformId = Platform_Windows_NT_2K_XP) And (lpVersionInformation.dwMajorVersion = 5) And (lpVersionInformation.dwMinorVersion = 1) Then
        OperatingSystem = System_Windows_XP
    End If
End Function

rafforum.rs - Forum Računarskog Fakulteta

Odgovor na temu