[RESENO] Koji je izbor Fja za pretragu?

[RESENO] Koji je izbor Fja za pretragu? 02.02.2016. u 20:38 · pre 130 meseci #1

Nov sam u excel-u i treba mi mala pomoc. Do sada sam to radio peške i sam računao ali me interesuje pomoću koje funkcije i kako to mogu da automatizujem.
U B koloni mogu biti samo četiri mogućnosti, Nema TM, Montaža, Servis, Demontaža i u zavisnosti od toga kolona c "Količina " se množi sa 500, 1300...
Koju formulu da iskoristim i kako da bih taj broj u kloni C u zavisnosti od "Realizacije" pomnožio i prikazao u koloni E " Dinara"?
Molim za pomoć

Potpis

www.pcela.iz.rs
Med ,polen, propolis i svi pčelinji proizvodi na jednom mestu. Pčelinjak Grujić
www.sitans.iz.rs
SITANS- zajedno smo jači
http://bs-quality.com/galerie/

Re: [RESENO] Koji je izbor Fja za pretragu? 02.02.2016. u 21:58 · pre 130 meseci #2

Jedan od načina je da koristiš VLOOKUP funkciju i bazu cijena za svaku realizaciju. U stupcu B možeš postaviti Data Validation padajući izbornik.
Formula za Excel 2003

Code:
=IF(ISERROR(VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2);"";VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2)

Formula za Excel 2007 i noviji (Data Validation u Excelu 2013)

Code:
=IFERROR(VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2;"")

vidi attach

milangru.xlsx27.59k

1

Re: [RESENO] Koji je izbor Fja za pretragu? 03.02.2016. u 06:15 · pre 130 meseci #3

Citat:

Jedan od načina je da koristiš VLOOKUP funkciju i bazu cijena za svaku realizaciju. U stupcu B možeš postaviti Data Validation padajući izbornik.
Formula za Excel 2003
Code:
=IF(ISERROR(VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2);"";VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2)

Formula za Excel 2007 i noviji (Data Validation u Excelu 2013)
Code:
=IFERROR(VLOOKUP(B2;$L$1:$M$4;2;FALSE)*C2;"")

vidi attach

Hvala Ivek33, još nisam stigao do formule VLOOKUP, mislim da je sledeća na redu, uspeo sam da rešim sa onim što znam SUMIF i formula izgleda ovako

Code:
=SUMIF(B3,"Montaža",C3)*1300+SUMIF(B3,"Nema TM",C3)*400+SUMIF(B3,"Demontaža",C3)*500+SUMIF(B3,"Servis",C3)*500

Umesto "Montaža" može i $L$2...

Potpis

www.pcela.iz.rs
Med ,polen, propolis i svi pčelinji proizvodi na jednom mestu. Pčelinjak Grujić
www.sitans.iz.rs
SITANS- zajedno smo jači
http://bs-quality.com/galerie/

Re: [RESENO] Koji je izbor Fja za pretragu? 03.02.2016. u 06:35 · pre 130 meseci #4

Sada me je =IFERROR(VLOOKUP funkcija veoma zainteresovala.
Nije mi jasno zašto se gleda cela tabela $L$1:$M$4 umesto samo $L$1:$L$4 (pošto su tu data validation opcije) i za čega se kotisti 2,FALSE?

Code:
=IFERROR(VLOOKUP(B2,$L$1:$M$4,2,FALSE)*C2,"")

Potpis

www.pcela.iz.rs
Med ,polen, propolis i svi pčelinji proizvodi na jednom mestu. Pčelinjak Grujić
www.sitans.iz.rs
SITANS- zajedno smo jači
http://bs-quality.com/galerie/

Re: [RESENO] Koji je izbor Fja za pretragu? 03.02.2016. u 10:17 · pre 130 meseci #5

Citat:

milangru:Nije mi jasno zašto se gleda cela tabela $L$1:$M$4 umesto samo $L$1:$L$4 (pošto su tu data validation opcije) i za čega se kotisti 2,FALSE?

Formula koju si napisao je "ugniježđena". Dakle Vlookup je ugniježđen unutar IFERROR funkcije. Što znači "ugniježđena funkcija" i kako se koristi pogledaj na linku.
IFERROR funkcija koristi se u Excelu 2007 i novijem a za određeni uvjet vraća rezultat ili praznu ćeliju (nulu) ili već što postaviš.

Da bi shvatio kako funkcionira VLOOKUP funkcija moraš razumjeti sintaksu i argumente.
Pogledaj ova dva tutorijala

- Vlookup Excel 2013
- Vlookup Excel 2003

S obzirom da se ovaj problem veže na jedan uvjet i potrebno je vratiti podatak iz istog reda ali određenog stupca za taj uvjet tada možemo koristiti Vlookup funkciju.
Sintaxa funkcije Vlookup

Code:
=VLOOKUP(lookup_value;table_array;col_index_num;range_lookup)

Dakle u ovom slučaju funkcija Vlookup za određeni uvjet iz B2 vraća podatak iz drugog stupca (broj 2) iz navedenog raspona (L1:M4).
Umjesto ovog broja 2 možeš koristii i funkciju COLUMN() koju ugnijezdiš na mjesto argumenta. Pogledaj tutorijale iz ovog posta.
FALSE je zadnji argument u funkciji a njegovo objašnjenje pogledaj na linku Range_Lookup (smeđi podnaslov)

Code:
VLOOKUP(uvjet-koji-tražimo;raspon-ćelija-u-kojem-tražimo-uvjet;broj-stupca-iz-kojega-vraćamo-rezultat;točan-podatak)

Raspon ćelija u kojem tražimo uvjet, uvijek se nalazi u prvom stupcu.

Funkcija Iferror

Code:
=IFERROR(vlookup-formula;ako-je-greška-vrati-?)

Što u prijevodu znači. Ako je rezultat formule Vlookup u redu, prikaži taj rezultat, a ako nije prikaži praznu ćeliju (ili što si već postavio za zadnji argument)
Ovaj problem može se riješiti na više načina, a sve zavisi o konstrukciji podataka. Npr. Ako želiš izbjeći postavljanje pomoćne baze u L1:M4

primjeri formula

Code:
=IF(B2="Nema TM";C2*100;IF(B2="Montaža";C2*200;IF(B2="Servis";C2*300;IF(B2="Demontaža";C2*400;""))))

Ako dodaš jedan stupac (npr. F) u kojem će biti redni brojevi za svaku stavku realizacije, tada možeš koristiti i ostale formule

Code:
=CHOOSE(MATCH(F2;{1;2;3;4});100;200;300;400)*C2

Code:
=CHOOSE(F2;100;200;300;400)*C2

Code:
=LOOKUP(F2;{1;2;3;4};{100;200;300;400})*C2

milangru-ivek33.xlsx11.56k

1

Re: [RESENO] Koji je izbor Fja za pretragu? 03.02.2016. u 12:04 · pre 130 meseci #6

Puno hvala, sada je mnogo jasnije!!!
HVALA još jednom.

Potpis

www.pcela.iz.rs
Med ,polen, propolis i svi pčelinji proizvodi na jednom mestu. Pčelinjak Grujić
www.sitans.iz.rs
SITANS- zajedno smo jači
http://bs-quality.com/galerie/

Re: [RESENO] Koji je izbor Fja za pretragu? 03.02.2016. u 15:41 · pre 130 meseci #7

Citat:

milangru:... uspeo sam da rešim sa onim što znam SUMIF i formula izgleda ovako ...

Formula sa SUMIF bi trebala ovako da izgleda:

Code:

=SUMIF(tblCenovnik[Usluga];A1;tblCenovnik[Cena])

Gde su [Usluga] i [Cena] kolone u tabeli tblCenovnik, a u A1 nam je "uslov" po kom vršimo sabiranje.

Nedostatak pretraživanja kao "sumiranja" je što se oslanja na specifičnost modela u kom postoji jedna-i-samo-jedna usluga u tabeli Cenovnika koja se tako zove. U nekom drugom modelu ovo ne mora da važi, tako da su f-je zamišljene baš za pretraživanje možda "prirodnije" u tom smislu.

U prilogu imaš po tri f-je kojima se do rešenja dolazi sumiranjem odnosno pretragom.

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

milangru-Izbor-Fje.xlsx10.56k

1

Forum kao aplikacija na telefonu

Srodne teme