Kako uvrstiti vreme u formulu

Kako uvrstiti vreme u formulu 05.01.2014. u 19:59 · pre 156 meseci #1

Pozdrav svima,

imam mali problem, ali nisam našao na rešenje za njega!
Ne znam na koji način da upišem vreme (sati, minute, sekunde) u formulu,
evo ga i primer:

=IF((AND(F3>"16:00:00";F3<"18:00:00")); "16-18"; "drugo vreme")

Ćelija F3 je formatirana kao Time, a kada je u F3 npr vreme 17:25:00 dobijam u G3 dobijam drugo vreme.
Inače, cela kolona F je dobro formatirana, jer kada selektujem više ćelija dobijam korektan zbir sati i minuta.
Pokušavao sam da vreme u formuli ubacim bez navodnika, sa apostrofom, sa uglasimt zagradama i dr, ali onda formula nije bila dobra. (znam da navodnici predstavljaju string, ali samo tako je Excel hteo da prihvati formulu).

Ako neko ima ideju ili rešenje ...
Inače, meni na pamet pada samo da posao odradim iz VBA ili da vreme podelim u dve kolone, tj posebno sate, a posebno minute, ali ovo poslednje rešenje mi se baš i ne sviđa jer onda gubim format vremena.

Hvala svima unapred

pozdrav

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 20:12 · pre 156 meseci #2

Možeš koristiti funkciju MEDIAN da proveriš da li je vrednost u traženom intervalu, tako da ti IF() nije neophodan - rezultat će biti Boolean, TRUE/FALSE.

Npr, ako je u F3 uneto vreme, u G3 možeš da uneseš

Code:
=F3=MEDIAN(F3;0+"16:";0+"18:")

Nulu sabiraš da bi se forsirao proračun tekstualne vrednosti. Ovo se ne preporučuje po nekima ali je "manji problem" od držanja granice intervala unutar formule. Ove vrednosti bi morale da su negde izvan i dostupne za izmenu.

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 20:47 · pre 156 meseci #3

Hvala na extra brzom odgovoru :)

Izvinjavam se što nisam bio dovoljno jasan prilikom postavljanja pitanja.
Meni treba da 24 časa podelim na 8 ili 12 intervala (jedan interval 2 ili tri sata)

Probao sam tvoj predlog i on funkcioniše, kada sam ga malo modifikovao dobio sam sledeće
=IF(F4=MEDIAN(F4;0+"16:";0+"18:");"16-18";IF(F4=MEDIAN(F4;0+"14:";0+"16:");"14-16")) i ovo takođ radi,

ali kada sam dodao i treći IF, excel nije hteo da ga prihvati:

=IF(F3=MEDIAN(F3;0+"16:";0+"18:");"16-18";IF(F3=MEDIAN(F3;0+"14:";0+"16:");"14-16");IF(F3=MEDIAN(F3;0+"12:";0+"14:");"12-14"))

Još jednom puno hvala, a ako imaš još neku ideju napiši

veliki pozdrav

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 21:04 · pre 156 meseci #4

Nisam siguran da sam shvatio.

Pokušaj sa MROUND da dobiješ umnožak intervala

Code:
=MROUND(C3;"2:")

Za interval od 2h, npr. Tvoj primer od 17:20 daje 18h, što je isti rezultat za oba intervala (jer 18h = 9x2h = 6x3h pa donju granicu event. možeš dobiti oduzimanjem

Code:
=MROUND(C3;"2:")-"2:"

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 21:41 · pre 156 meseci #5

Ne ide, MROUND ne funkcioniše.

U koloni F imam oko 1000 vremena.

Za sada ću privremeno da rešim problem tako što ću filtrirati vrednosti pomoću Number filters --> Between, pa ću ručno u kolonu G upisati intervale.
Ovako ću relativno brzo dobiti željeni rezultat (par min), ali ipak nisam zadovoljan, jer nisam postigao automatski upis.

Još jednom hvala puno na trudu i brzim odgovorima

pozdrav

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 22:04 · pre 156 meseci #6

Možda ovako nešto

Code:
=(MROUND(C3;2/24)-2/24)*24 & "-" & MROUND(C3;2/24)*24

-za intervale od 2h i

Code:
=(MROUND(C3;3/24)-3/24)*24 & "-" & MROUND(C3;3/24)*24

-za po 3h.

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

Re: Kako uvrstiti vreme u formulu 05.01.2014. u 23:02 · pre 156 meseci #7

3okc hvala ti, radi savršeno, jedino za deo koji se odnosi na gornji sat prikazuje sledeću gornju vrednost.
Ne znam baš da objasnim, pa sam kopirao deo.
Pokušaću sutra popodne to da rešim (moram ujutru na posao :(

17:12:00 16-18
2:25:00 0-2
6:30:00 4-6
22:10:00 20-22
18:20:00 16-18
7:35:00 6-8
2:28:00 0-2
2:13:00 0-2
19:30:00 18-20
12:30:00 10-12
15:30:00 14-16
5:20:00 4-6
2:00:00 0-2
12:40:00 10-12
4:55:00 2-4
6:50:00 4-6
9:00:00 8-10

U svakom slučaju, još jednom puno hvala
pozdrav

Re: Kako uvrstiti vreme u formulu 06.01.2014. u 00:03 · pre 156 meseci #8

Ili možda ovako

Code:
=MROUND(ROUNDUP(C3*24;0);2)-2 & "-" & MROUND(ROUNDUP(C3*24;0);2)
=MROUND(ROUNDUP(C3*24;0);3)-3 & "-" & MROUND(ROUNDUP(C3*24;0);3)

Ustvari.. bolje ovako

Code:
=INT(C3*24/2)*2 & "-" & INT(C3*24/2)*2+2
=INT(C3*24/3)*3 & "-" & INT(C3*24/3)*3+3

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

Re: Kako uvrstiti vreme u formulu 06.01.2014. u 14:58 · pre 156 meseci #9

Sve radi savršeno!!!!!

3okc hvala puno na pomoći :)

pozdrav

Forum kao aplikacija na telefonu

Srodne teme