Tema
Boje
Pismo
Registracija

Novo

Forum kao aplikacija na telefonu

Dodajte forum na početni ekran i koristite ga kao aplikaciju, sa menijem na dnu ekrana.

Kako se dodaje

private function()

Odgovori Nova tema
Štampanje RSS teme Kopiraj vezu do teme Podeli na Facebook-u Podeli na X-u (Twitter) Idi na poslednju poruku
  • 3 odgovora
  • 2.906 pregleda

Najnovija ↓

private function() 24.04.2006. u 18:49 · pre 249 meseci #1
U funkciji loadXML() postoji trace koji vraca sve elemente xml fajla i on radi. Kada njega komentujem, a odkomentujem trace u f-ji array(), dobijam error "There is no property with the name 'my_ar." Problem je sledeci: Kako da iz f-je array() pristupim promenljivoj my_ar koja je definisana u f-ji loadXML().

class pitanje extends MovieClip {

var i:Number;

function pitanje() {
loadXML();
array();
}

private function loadXML() {
var xmlData:XML;
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = function(ok) {
if (ok) {
goto(xmlData);
}
};
xmlData.load("pitanje.xml");
function goto(thisXML) {
var rootNode = thisXML.firstChild;
for (i=0; i<rootNode.childNodes.length; i++) {
var my_ar = new Array();
my_ar = rootNode.childNodes.firstChild.nodeValue;
trace(my_ar)
}
}
}
private function array() {
//trace(my_ar)
}
}

xml fajl:

<?xml version="1.0" encoding="utf-8"?>
<pictures>
<name>auto</name>
<name>kuca</name>
<name>avion</name>
<name>kamion</name>
<name>lopta</name>
<name>olovka</name>
<name>knjiga</name>
</pictures>
Re: private function() 24.04.2006. u 19:21 · pre 249 meseci #2
problem je sto ti je my_ar bila lokalna varijabla u funkciji,
kad je deklarises u klasi i inicijalizujes u konstruktoru onda neces dobijati
"There is no property with the name 'my_ar." error.

Mada moj predlog ti je da promenis ime f-je iz Array, obzirom da je to reserved keyword.

Code:

class pitanje extends MovieClip {
    var i:Number;
    var my_ar:Array; 
    function pitanje() {
        my_ar = new Array();
        loadXML();
        array();
    }
    private function loadXML() {
        var xmlData:XML;
        xmlData = new XML();
        xmlData.ignoreWhite = true;
        xmlData.onLoad = function(ok) {
            if (ok) {
                goto(xmlData);
            }
        };
        xmlData.load("pitanje.xml");
        function goto(thisXML) {
            var rootNode = thisXML.firstChild;
            for (i=0; i<rootNode.childNodes.length; i++) {
                //var my_ar = new Array();
                my_ar = rootNode.childNodes.firstChild.nodeValue;
                trace(my_ar);
            }
        }
    }
    private function array() {
        trace(my_ar)
    }
}

Potpis
Idle mind is the devils playground, in my case it turned out to be an amusement park.

Sustina problema ove zemlje:
Legeonar_: Sto pre treba da shvatite da je EU propast i da se tamo mora raditi,a ne samo biti zaposlen.
http://www.elitemadzone.org/p1864861

Nobody Remains Virgin, Life Fucks Everyone
Re: private function() 26.04.2006. u 14:37 · pre 249 meseci #3
Hvala na trudu, ali onda ne mogu da trejsujem elemente iz XML-a.
Re: private function() 26.04.2006. u 15:28 · pre 249 meseci #4
U pravu si, tako mi i treba kad odgovaram na frku.
Nego, ako sam dobro razumeo ti hoces vrednost svakog name node-a da stavis u Array i da mozes da mu pristupas iz druge funkcije.
Ukoliko je to slucaj, onda je ovo kod za Flash 8

Code:

import mx.utils.Delegate;

class pitanje extends MovieClip {
    // declare vars needed for class
    private var i:Number;
    private var my_ar:Array; 
    private var xmlData:XML;
    
    // initialize the vars, set the XML Object to ignore the white space,
    // set the function that will be called for the XML onLoad event
    function pitanje() {
        my_ar = new Array();
        xmlData = new XML();
        xmlData.ignoreWhite = true;
        xmlData.onLoad = Delegate.create(this,goto);
        
        loadXML();
        // if you call array function here you will get nothing back, 
        // since the loading has been started, it may not have completed yet
        //array();
    }
    
    // start the loading of the xml file
    private function loadXML() {
        trace("loadXML");
             
        xmlData.load("pitanje.xml");
        
    }
    
    
    //function that is called when the xml file is loaded,
    // param success will be true for successfull loading of the xml file
    function goto(success) {
        if (success) {
            // trace the whole xml file 
            trace(xmlData)
            // set the root node
            var rootNode:XMLNode = xmlData.firstChild;
            // go through all the childnodes in the root node
            for (i=0; i<rootNode.childNodes.length; i++) {
                //var my_ar = new Array();
                // and add their text values to the array
                my_ar.push(rootNode.childNodes[i].firstChild);
                // trace the current content of the my_ar array
                trace("my_ar = " + my_ar);
            }
            
            // when you call the function here it will list the contents of 
            // the array, because the load has been completed and the xml
            // has been parsed
            array();
        } else {
            trace("crap")
        }
    }
    
    // list the contents of the my_ar array
    private function array() {
        trace("array = " + my_ar)
    }
}


output ove klase je:
Code:

loadXML
<?xml version="1.0" encoding="utf-8"?><pictures><name>auto</name><name>kuca</name><name>avion</name><name>kamion</name><name>lopta</name><name>olovka</name><name>knjiga</name></pictures>
my_ar = auto
my_ar = auto,kuca
my_ar = auto,kuca,avion
my_ar = auto,kuca,avion,kamion
my_ar = auto,kuca,avion,kamion,lopta
my_ar = auto,kuca,avion,kamion,lopta,olovka
my_ar = auto,kuca,avion,kamion,lopta,olovka,knjiga
array = auto,kuca,avion,kamion,lopta,olovka,knjiga

Potpis
Idle mind is the devils playground, in my case it turned out to be an amusement park.

Sustina problema ove zemlje:
Legeonar_: Sto pre treba da shvatite da je EU propast i da se tamo mora raditi,a ne samo biti zaposlen.
http://www.elitemadzone.org/p1864861

Nobody Remains Virgin, Life Fucks Everyone
Odgovori
Prijavite se da biste odgovorili u ovoj temi.PrijavaRegistracija

Premeštanje teme