[Excel] Izdvajanje stringa iz celije

[Excel] Izdvajanje stringa iz celije 29.11.2007. u 10:59 · pre 230 meseci #1

U celiji se nalazi zapis u sledecem obliku:

string1 ; string2 ; string3 ....; stringN

Kako da izdvojim poslednji string, string koji se nalazi nakon poslednjeg simbola ";" ?

Resenje mi je potrebno primenom Excel formula, bez VBA koda.

Ako bih uspeo da okrenem citav "zapis" vrlo lako bih mogao da resim problem sa find funkcijom ...

_{[Ovu poruku je menjao chuPavi dana 29.11.2007. u 12:27 GMT+1]}

Re: [Excel] Izdvajanje stringa iz celije 29.11.2007. u 12:11 · pre 230 meseci #2

Neka se original string nalazi u A1. Ukoliko izvršiš zamenu ; sa praznim stringom i napraviš razliku dužine originala i nakon manipulacije dobićeš koliko puta se u stringu pojavljuje znak ;

Code:
=LEN(A1)-LEN(SUBSTITUTE(A1,";",""))

Sad u originalnom stringu možeš da izvršiš zamenu poslednjeg znaka ; sa nekim specijalnim znakom koji se ne pojavljuje u stringu npr "^^"

Code:
=SUBSTITUTE(A1,";","^^",LEN(A1)-LEN(SUBSTITUTE(A1,";","")))

i onda odsečeš zadnji deo stringa od pozicije tog znaka.
Konačna formula:

Code:
=RIGHT(A1,LEN(A1)-SEARCH("^^",SUBSTITUTE(A1,";","^^",LEN(A1)-LEN(SUBSTITUTE(A1,";","")))))

Potpis

Nije to loše Rembrante, samo što ne bi dodao još malo boje?

Re: [Excel] Izdvajanje stringa iz celije 29.11.2007. u 12:46 · pre 230 meseci #3

Uh, kako je ovo dobro :)

Po meni, funkcija SUBSTITUTE sa svojim poslednjim argumentom resava ovaj problem.

A jel postoji resenje za invertovanje stringa iz excela ?

Re: [Excel] Izdvajanje stringa iz celije 29.11.2007. u 13:20 · pre 230 meseci #4

Relativno je lako navraviti korisničku funkciju koja to radi. Takođe moguće je ukoliko je tekst već podeljen na karaktetre (u posebnim ćelijama) nešto uraditi sa matričnom forumulom. Ovako, korišćenjem standardnih funkcija ne znam.

Potpis

Nije to loše Rembrante, samo što ne bi dodao još malo boje?

Re: [Excel] Izdvajanje stringa iz celije 30.11.2007. u 09:42 · pre 230 meseci #5

Kako dopraviti ovo resenje tako da pokriva mogucnosti da je celija a1 prazna ili da je u njoj upisan samo jedan string, sto znaci bez simbola ";"

Code:
=RIGHT(A1,LEN(A1)-SEARCH("^^",SUBSTITUTE(A1,";","^^",LEN(A1)-LEN(SUBSTITUTE(A1,";","")))))

Sve sto sam pokusao da napisem je ispalo predugacko, takoreci u 3 reda, uspeo sam da skratim na 2 ali sa IFERROR funkcijom koja ne radi u Excel 2003

Re: [Excel] Izdvajanje stringa iz celije 30.11.2007. u 10:06 · pre 230 meseci #6

Evo kako sam ga ja skrpio:

Code:
=IF(ISBLANK(VLOOKUP($A2,STSve,36,FALSE)),"",IF(ISERR(FIND(";",VLOOKUP($A2,STSve,36,FALSE))),VLOOKUP($A2,STSve,36,FALSE),RIGHT(VLOOKUP($A2,STSve,36,FALSE),LEN(VLOOKUP($A2,STSve,36,FALSE))-SEARCH("^^",SUBSTITUTE(VLOOKUP($A2,STSve,36,FALSE),";","^^",LEN(VLOOKUP($A2,STSve,36,FALSE))-LEN(SUBSTITUTE(VLOOKUP($A2,STSve,36,FALSE),";","")))))))

Kako bih mogao da se otresem ponavljanja "VLOOKUP($A2,STSve,36,FALSE)"

Re: [Excel] Izdvajanje stringa iz celije 30.11.2007. u 12:27 · pre 230 meseci #7

Interesantno rešenje preko formule.

A sve je moglo i drugačije "da je Pera odmah otišao u policiju". :D
Alternativa: sortiranje brojeva tipa 123/07
(ujedno bi trebalo i da reši prethodno pitanje)

A ako baš mora formula, pa ubaci Pecino rešenje u jedan IF.
npr: IF(CELL IS BLANK; NOTHING; OTHERWISE)..

Potpis

Have you found helpful examples, solutions or ideas-in-work, please consider the
following:
• Citation of *actual page* you are going to using is welcome.
• Have you saw "Value Added" examples you are going to incorporate to your
profitable blog, daily job or any money making venture: How about online donation?
↗Ana & Vlade Divac Foundation
Hvala!

Srodne teme