[es] - Compact & Repair Access baze kroz ASP?

impact
Vladimir Golušin
Kikinda

Član broj: 2517
Poruke: 109
212.200.76.*

Sajt: www.2point.co.yu

Profil

Re: Compact & Repair Access baze kroz ASP?

^{21.06.2002. u 03:49}

Ne! Moje pitanje je prosto. Da li neko zna kako je moguce uraditi
Compact & Repair baze pomoću čistog ASP koda? Jer posle puno
pisanja i brisanja baza mora da se sredi - a to se radi pomocu
Compact & Repair naredbe u Accessu. E sad, ovo je moguce uraditi
pomocu cistog ASP-a, ali ja sam pronasao jedan primer (sa Microsoft-ovog
sajta) koji ama bas nista ne uradi nad bazom! Znaci nacin postoji, samo
me interesuje koji!

^{21.06.2002. u 03:49}

brckodc
Aleksandar Milošević
SweaSAT administrator wireless sistema, Brcko, BiH
Brčko

Član broj: 32275
Poruke: 5
*.teol.net.

ICQ: 114617350
Sajt: www.brcko.co.ba

Profil

Re: Compact & Repair Access baze kroz ASP?

^{24.05.2005. u 08:57}

<%
Dim str_db_path_name
str_db_path_name = server.mapPath(".") & "\" & "baza.mdb"

'Dimension variables
Dim objJetEngine
Dim objFSO
Dim strCompactDB
DIm strCon
DIm adoCon
%>

<%
Set adoCon = Server.CreateObject("ADODB.Connection")

adoCon.connectionstring = strCon
strCon = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & str_db_path_name
%>

<%
'Pokretanje compact i repair funkcije
If Request.Form("postBack") Then %>
<ol><%

'kreiranje FSO objekta
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

'backup baze
objFSO.CopyFile str_db_path_name, Replace(str_db_path_name, ".mdb", "-backup.mdb", 1, -1, 1)

Response.Write(" <li class=""bold"">Napravljen je backup baze podataka na:- " & Replace(str_db_path_name, ".mdb", "-backup.mdb", 1, -1, 1) & " </li>")

'kreiranje JET engine objekta
Set objJetEngine = Server.CreateObject("JRO.JetEngine")

'odrediste i naziv kompaktovane baze
strCompactDB = Replace(str_db_path_name, ".mdb", "-tmp.mdb", 1, -1, 1)

'kompaktovanje
objJetEngine.CompactDatabase strCon, "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & strCompactDB

'ispis teksta kreiranja nove kompaktovanja baze
Response.Write(" <li class=""bold"">Nova optimizovana baza:- " & strCompactDB & " </li>")

'resetovanje Jet objekta
Set objJetEngine = Nothing

'brisanje stare baze
objFSO.DeleteFile str_db_path_name

'ispis teksta brisanja stare baze
Response.Write(" <li class=""bold"">Nova ne optimizovana baza je obrisana:- " & str_db_path_name & " </li>")

'preimenovanje privremene baze u stari naziv
objFSO.MoveFile strCompactDB, str_db_path_name

'ispis teksta brisanja stare baze
Response.Write(" <li class=""bold"">Izmjenjen je naziv optimizovane baze sa:- " & strCompactDB & " na:- " & str_db_path_name & " </li>")

'resetovanje FSO objekta
Set objFSO = Nothing

Response.Write("Baza podataka je optimizovana i napravljen je backup!")

%></ol>

<% Else %>
Napomena: Ako optimizacija ne uspije, biće urađen backup baze podataka čiji naziv ima nastavak '-backup.mdb'.
<form action="backup_db.asp" method="post" name="frmCompact" id="frmCompact">
<input name="postBack" type="hidden" id="postBack" value="true">
<input type="submit" name="Submit" value="OPTIMIZUJ I NAPRAVI BACKUP">
</form>
<% End If %>

Alex M.

^{24.05.2005. u 08:57}