Code:
'Example by Howard Henry Schlunder
' This example requires one command button (Command1)
Private Declare Function GetVersion Lib "kernel32" () As Long
Private Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" _
(ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, _
lpSecurityAttributes As Any, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, _
ByVal hTemplateFile As Long) As Long
Private Declare Function DeviceIoControl Lib "kernel32" (ByVal hDevice As Long, _
ByVal dwIoControlCode As Long, lpInBuffer As Any, ByVal nInBufferSize As Long, lpOutBuffer As Any, _
ByVal nOutBufferSize As Long, lpBytesReturned As Long, lpOverlapped As Any) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Const INVALID_HANDLE_VALUE = -1
Private Const OPEN_EXISTING = 3
Private Const FILE_FLAG_DELETE_ON_CLOSE = 67108864
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const IOCTL_STORAGE_EJECT_MEDIA = 2967560
Private Const VWIN32_DIOC_DOS_IOCTL = 1
Private Type DIOC_REGISTERS
reg_EBX As Long
reg_EDX As Long
reg_ECX As Long
reg_EAX As Long
reg_EDI As Long
reg_ESI As Long
reg_Flags As Long
End Type
Private Sub Command1_Click()
Dim hDrive As Long, DummyReturnedBytes As Long
Dim EjectDrive As String, DriveLetterAndColon As String
Dim RawStuff As DIOC_REGISTERS
EjectDrive = InputBox("Which drive shall we try to eject the media from?", "Eject Media")
If Len(EjectDrive) Then 'Confirm the user didn't cancel
DriveLetterAndColon = UCase(Left$(EjectDrive & ":", 2)) 'Make it all caps for easy interpretation
If GetVersion >= 0 Then 'We are running Windows NT/2000
hDrive = CreateFile("\\.\" & DriveLetterAndColon, GENERIC_READ Or GENERIC_WRITE, 0, ByVal 0, OPEN_EXISTING, 0, 0)
If hDrive <> INVALID_HANDLE_VALUE Then
'Eject media!
Call DeviceIoControl(hDrive, IOCTL_STORAGE_EJECT_MEDIA, 0, 0, 0, 0, DummyReturnedBytes, ByVal 0)
Call CloseHandle(hDrive) 'Clean up after ourselves
End If
Else 'We are running Win9x/Me
hDrive = CreateFile("\\.\VWIN32", 0, 0, ByVal 0, 0, FILE_FLAG_DELETE_ON_CLOSE, 0)
If hDrive <> INVALID_HANDLE_VALUE Then
'Setup our raw registers to use Interrupt 21h Function 440Dh Minor Code 49h
RawStuff.reg_EAX = &H440D 'The function to use
RawStuff.reg_EBX = Asc(DriveLetterAndColon) - Asc("A") + 1 'The drive to do it on
RawStuff.reg_ECX = &H49 Or &H800
'The minor code of the function in the low byte of the low word and the device category of 8 in the high byte of the low word
'Eject media!
Call DeviceIoControl(hDrive, VWIN32_DIOC_DOS_IOCTL, RawStuff, LenB(RawStuff), RawStuff, LenB(RawStuff), DummyReturnedBytes, ByVal 0)
Call CloseHandle(hDrive) 'Clean up after ourselves
End If
End If
End If
End Sub
VB kod za eject cd?
Registrovani: 124 ( acapn91, mlputak, mluddn, vladale016, bojanmax, teta_lija, ptomic, milanche, BiiigMuzzy, radosm, sorrow, vatri, mischo, frenk, sonus70, marija12-return, zarkodj, MarcusS, vladak3, srdjan_kg, VUJTA, .qwerty., pajo sspa, zeoN_Rider, veljkoE, Hans_D, exmetakom, IceThunder, tvitica, glisa05, Crnja, niceness, batancev, Man-Wolf, stsung, abyss, mmilenkovic, pajaja, buda01, 987654, bulat666, Miloja, tesla017, gazd, Med, karas, Ecrabera, itf, stavrula, lazamil, igorko, vladajeca, josip77, oPEN, _goThic_, dajo, night-shift, bup, Cileinteractiv, Mladen, acoobradovic, Skeneropulos, milenak, rajan21, srpsko gradjevinarstvo, DrSimke, kumkat, BlackNeo, laki-91, rumeni, dobar_decko, Profajler, vriskica, snajder, term it, smars, djole_za, Vic, griva, Skaarj, delevre, toleander, mmv, egavas, Goran Rakić, Copyright, _MarkoS, stolay, Vranac, Davor Vlajkovic, vlado95, X-it, Zlaja.Kol, spalikus72, barcode, bgo, bgo, tahuti, Apatrid, R A V E N, markodjorem, srdjansto, Burgos, fade, Masamunea, yu1ny, zemun88, dj011, jsmith, Nebojsa Milanovic, apex, optix, Deedlit, bax033, najsladja0905, Srki__, miks3r, spulkan, zilenk, nk_sm, Jovan Prokopović, tihanavuk, MasterElektroniK, Fedya )
Re: VB kod za eject cd?
Re: VB kod za eject cd?
Re: VB kod za eject cd?