Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.

Rename otvoreni word dokument

[es] :: Office :: Word :: Rename otvoreni word dokument

Strane: 1 2

[ Pregleda: 4518 | Odgovora: 26 ] > FB > Twit

Postavi temu Odgovori

Autor

Pretraga teme: Traži
Markiranje Štampanje RSS

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Rename otvoreni word dokument04.08.2018. u 11:49 - pre 68 meseci
Da li postoji mogucnosti da rename otvorenog word dokumenta, ili nekom opcijom ili pomocu macro-a?

nasao sam dva macro ali svaki mi pokazuje neku gresku.

1. macro 1

Sub RenameDocumentWithDate()
Dim strDocName, strDocNameNoExten, strDocFullName, strDocPath As String
Dim strNewDocName As String
Dim KillFile As String
Dim strDate As String

' Get the current doc name.
strDocName = ActiveDocument.Name
strDocFullName = ActiveDocument.FullName
strDocNameNoExten = Left(strDocName.Name, Len(strDocName.Name) - 5)
strDocPath = ActiveDocument.Path
strDate = Format(Date, "mm - dd - yyyy")

If strDocPath = "" Then
MsgBox ("This document hasn't been saved. You can't rename it.")
Exit Sub
End If

' Save the doc in new name with date.
ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
KillFile = strDocFullName
Kill KillFile
End Sub


run time error `438`
object dosn`t support this property or method
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument04.08.2018. u 19:15 - pre 68 meseci
Treba prepraviti deo koda u ovom kodu sto je dat:

Code:

strDocNameNoExten = Left(strDocName.Name, Len(strDocName.Name) - 5)


na

Code:

strDocNameNoExten = Left(strDocName, Len(strDocName) - 5)


Takodje ako fajl nije snimljen pre toga, onda ce strDocPath biti prazan string i javice se MsgBox kako je predvidjeno u source code-u.

Tu se moze dodati parce koda da onda bar pita za lokacuju i pozove dialog za 'browse for folders' ili klasican File Save As dialog.

Ovaj ceo kod moze da se stavi u tkz. NORMAL TEMPLATE deo kako bi bio dostupan uvek i da ne mora da se ubacuje u svaki dokument.
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument04.08.2018. u 23:22 - pre 68 meseci
opet isto error, sada ovde javlja se problem

ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument05.08.2018. u 02:20 - pre 68 meseci
1. Koja verzija Word je u pitanju i gde je postavljen kod tj kako isti izvrsava?

2. Koje su vrednosti za dole navedene promenljive neposredno pre izvrsvanja koda 'If strDocPath = "" Then'

strDocName
strDocFullName
strDocNameNoExten
strDocPath
strDate

3. Da li imas privilegije da mozes da upises fajl na lokaciji gde pokusavas da snimis isti? Probaj da snimis fajl na desktop posto tu uvek treba da imas privilegije da mozes i da citas i da pises i da brises tj. r/w.

4. Evo screenshotova da radi.







Evo koda:

Code:

Sub RenameDocumentWithDate()
    Dim strDocName, strDocNameNoExten, strDocFullName, strDocPath As String
    Dim strNewDocName As String
    Dim KillFile As String
    Dim strDate As String

    ' Get the current doc name.
    strDocName = ActiveDocument.Name
    strDocFullName = ActiveDocument.FullName
    strDocNameNoExten = Left(strDocName, Len(strDocName) - 5)
    strDocPath = ActiveDocument.Path
    strDate = Format(Date, "mm - dd - yyyy")
    
    Debug.Print strDocName
    Debug.Print strDocFullName
    Debug.Print strDocNameNoExten
    Debug.Print strDocPath
    Debug.Print strDate

    If strDocPath = "" Then
        MsgBox ("This document hasn't been saved. You can't rename it.")
        Exit Sub
    End If

    ' Save the doc in new name with date.
    ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
    KillFile = strDocFullName
    Kill KillFile
    
End Sub
Prikačeni fajlovi
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument05.08.2018. u 08:26 - pre 68 meseci
opet isto.

koristim 2007.

snimljeno na desktopu.

u prilogu greska i kod koji sam ubacio.


Prikačeni fajlovi
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument05.08.2018. u 15:58 - pre 68 meseci
Verovatno da Word 2007 nema podrsku za komandu koja se poziva - ActiveDocument.SaveAs2.

To mozes da proveris preko Object Browser-a u VBA. Imas dole sliku kako.

Takodje mozes da izmenis red da umest SaveAs2 bude SaveAs


Code:

ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate


u

Code:

ActiveDocument.SaveAs FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate




Prikačeni fajlovi
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument05.08.2018. u 19:12 - pre 68 meseci
kada sam uradio bez saveas2 samo snimio isto ime i dodao datum a nece kao u adresi ispod, da mi ponudi da rename file>

https://www.datanumen.com/blog...art-ways-rename-document-word/
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument05.08.2018. u 21:00 - pre 68 meseci
Nece da te pita za ime zato sto u kod nemas deo za to da te pita jer fali InputBox f-ja.

Ako pogledas kod koji se nalazi na linku koji si prosledio videces dole navedeni deo kod da je prisutan.

Code:

 '  Pop up an input box for new name.
  strNewDocName = InputBox("Enter a new name for this document:", "Rename document", strDocName)


Ja sam ti preradio malo kod i dodao podrsku za obe varijante SaveAs i SaveAs2, gde se ustvari na osnovu verzije Word koristi odredjena komanda.
Ako je u pitanju Word 2007 i stariji onda se koristi SaveAs a ako je novija verzija od Word 2007 onda se koristi SaveAs2.

Takodje u prilogu imas sliku na kojoj predlazem da na isti nacis smestis kod za ovo i da ga kasnije malo sredis i optimizujes.
Tako ubacen kod kao makro mozes posle da 'nakacis' na neki 'button' u Toolbaru ili Menu-ju.

U nastavku doradjen kod:

Code:


Sub RenameDocumentWithDate()

    Dim strDocName, strDocNameNoExten, strDocFullName, strDocPath As String
    Dim strNewDocName As String
    Dim KillFile As String
    Dim strDate As String

    ' Get the current doc name.
    strDocName = ActiveDocument.Name
    strDocFullName = ActiveDocument.FullName
    strDocNameNoExten = Left(strDocName, Len(strDocName) - 5)
    strDocPath = ActiveDocument.Path
    strDate = Format(Date, "mm - dd - yyyy")
    
    Debug.Print strDocName
    Debug.Print strDocFullName
    Debug.Print strDocNameNoExten
    Debug.Print strDocPath
    Debug.Print strDate

    If strDocPath = "" Then
        MsgBox ("This document hasn't been saved. You can't rename it.")
        Exit Sub
    End If

    '  Pop up an input box for new name.
    strNewDocName = InputBox("Enter a new name for this document:", "Rename document", strDocName)
    
    ' Check MS Word version
    ' Word versions are 15 - 2013, 14 -> 2010, 12 - 2007, 11 - 2003
    ' If MS Word version is newer then MS Word 2007 then
    If Val(Application.Version) > 12 Then
        
        ' Save the doc in new name with date.
        ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
        
    ' If MS Word version is 2007 or older then
    Else
    
        ' Save the doc in new name with date.
        ActiveDocument.SaveAs FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
    
    End If
    
    KillFile = strDocFullName
    Kill KillFile
    
End Sub



p.s. Ja nemam ovde nigde instaliran MS Word 2007 tako da nisam bio u mogucnosti da proverim da li ovo radi ali opet treba da radi bez problema. Kod je inace radjen na MS Word 2013. Videcu ako budem stigao pa da probam bas eto cisto i MS Word 2007.
Prikačeni fajlovi
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 01:22 - pre 68 meseci
Stigao sam da proverim sa MS Word 2007.
Kod radi bez problema.
U prilogu su screenshotovi.
Prikačeni fajlovi
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 15:34 - pre 68 meseci
ne znam da li sam dobro uradio, ali kada mi se pojavi dijalog da upisem ime fajla, i upisem drugo ime fajla, snimi se onako kako je bilo samo dodat datum.

npr.ime fajla mi je `new document`, on snimi kao `new document 08 - 06 - 2018`, a treba da ga snimi `moj fajl`. to ne uspeva, nije nuzno da bude datum pored iemna fajla.
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 17:03 - pre 68 meseci
Zameniti

'strDocNameNoExten' ako se hoce sa datumom u nastavku

ili

'strDocNameNoExten & " " & strDate' ako se hoce bez datuma

sa

'strNewDocName' vrednoscu, posto se vrednost iz inputbox-a smesta u 'strNewDocName' promenljivu.



Ja nisam pitao a sta se tacno pravi i zeli postici ovim kodom kao finalni rezultat?
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
*.internet.mts.telekom.rs.



+2 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 17:53 - pre 68 meseci
krajnji rezultat da snimljeni prvi fajl npr.zove se file1, kada se otvori da se tako otvoren preimenuje na npr.dokumen, ili neko drugo ime.


imam mnogo dokumenata koje treba ds preimenujem ali ne mogu da znam kako dok ne otvorim
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 18:06 - pre 68 meseci
1. Trenutno otvoreni file se zove 'Doc1'

2. Kod treba da odradi kad se izvrsi:

3. Da predlozi i pita za novo ime file-a (sa/bez datuma) - koristeci inputbox?

4. Snimi file pod novim imenom na istoj lokaciji i

5. Obrise postojece file 'Doc1' koji se nalazi na istoj lokaciji

?

Takodje u opisu nisi jasno rekao da li je naziv file-a sa/bez datuma.
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 19:48 - pre 68 meseci
u prilogu sta se desava.

ime dokumenta je proba proba 1, i ja bih da preimenujem novo ime dokumenta, a on ga sam preimenuje u proba proba 1 06-08-2018
Prikačeni fajlovi
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 20:56 - pre 68 meseci
Znaci nije potrebno da se dodaje u nazivu file-a datum kao sto je primer i kao sto je bilo s' pocetka.

Brzinski sam ti dodao sve okvirno u kodu sta je trazeno u poslednjoj poruci.

Nadam se da je sad to to.

Takodje, sugestija dobronameran je da ubuduce se definise sta se hoce i da se odradi idejno koncept sta se hoce kako bi se to posle pretvorilo u kod.

Sve sto se gore pisano je malo konfuzno i nije bas lepo definisano... (nije zlurado vec opet dobronamerno receno).

Ostavio samo delove koda u komentarima cisto da mozes da vidis razlike i da mozes malo da prostudiras kod posto vidim da se nema bas puno iskustva sa VBA.

Code:

Sub RenameDocumentWithDate()

    Dim strDocName, strDocNameNoExten, strDocFullName, strDocPath As String
    Dim strNewDocName As String
    Dim SaveAsFilename As String

    ' Get the current doc name
    strDocName = ActiveDocument.Name
    
    ' Get current full filename
    strDocFullName = ActiveDocument.FullName
    
    ' Get current filename path only
    strDocPath = ActiveDocument.Path
    
    ' Get current filename extension - since can be 3 or 4 char. len e.g. filename.doc || filename.docx  ...
    strDocExt = Right(strDocName, Len(strDocName) - InStrRev(strDocName, "."))
    
    ' Old > strDocNameNoExten = Left(strDocName, Len(strDocName) - 5)
    
    ' Set current filename without extension
    strDocNameNoExten = Left(strDocName, Len(strDocName) - (Len(strDocExt) + 1))
    
    ' If Document path isn't set then
    If strDocPath = "" Then
        
        ' Show messagebox to user
        MsgBox ("This document hasn't been saved. You can't rename it.")
        Exit Sub
        
    End If

    ' Pop up an input box for new name.
    ' Old > strNewDocName = InputBox("Enter a new name for this document:", "Rename document", strDocName)
    strNewDocName = InputBox("Enter a new name for this document:", "Rename document", strDocNameNoExten)
    
    ' If new filename isn't set then exit
    If Len(Trim(strNewDocName)) = 0 Then
        
        ' Show messagebox to user
        MsgBox ("Name of this document hasn't been set. You can't save it.")
        Exit Sub
        
    End If
    
    ' If filename is same and already exists
    If LCase(strNewDocName) = LCase(strDocNameNoExten) Then
        
        ' If current file already exists then
        If Dir(strDocFullName) <> "" Then
            
            ' Show messagebox to user
            MsgBox ("You can't use same name of file for saving." & vbCrLf & "Please try again by entering a diffrent filename.")
            Exit Sub

        End If
        
    End If
    
    ' If backslash isn't present on the end of path then add it
    If Right(strDocPath, 1) <> "\" Then strDocPath = strDocPath & "\"
    
    ' Create filename with full location where will be saved
    SaveAsFilename = strDocPath & strNewDocName
    
    Debug.Print "Document name:", strDocName
    Debug.Print "Document name without ext.:", strDocNameNoExten
    Debug.Print "Document full name:", strDocFullName
    Debug.Print "Document path:", strDocPath
    Debug.Print "New document name:", strNewDocName
    Debug.Print "Save document as filename:", SaveAsFilename
    
    ' Check MS Word version
    ' Word versions are 15 - 2013, 14 -> 2010, 12 - 2007, 11 - 2003
    ' If MS Word version is newer then MS Word 2007 then
    If Val(Application.Version) > 12 Then
        
        
        ' Old > ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
        ' ActiveDocument.SaveAs2 FileName:=strDocPath & "\" & strNewDocName
        
        ' Save current document with new filename
        ActiveDocument.SaveAs2 FileName:=SaveAsFilename
        
        
    ' If MS Word version is 2007 or older then
    Else
    
        
        ' Old > ActiveDocument.SaveAs FileName:=strDocPath & "\" & strDocNameNoExten & " " & strDate
        ' ActiveDocument.SaveAs FileName:=strDocPath & "\" & strNewDocName
        
        ' Save current document with new filename
        ActiveDocument.SaveAs FileName:=SaveAsFilename
    
    End If
    
    On Error Resume Next
    
    ' Delete current (original) file
    Kill strDocFullName
    
    ' If there was any error when deleting a file from given location then
    If Err.Number <> 0 Then
        
        ' Show message to user
        MsgBox "Error in deleting file for given location." & vbCrLf & vbCrLf & "Error " & Err.Number & " - " & Err.Description, vbCritical, "Saving document"
        
    End If
    
    Err.Clear
    
End Sub

 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 21:05 - pre 68 meseci
sad radi, to je to.

pokusao sam sto bolje da objasnim, ali izgleda da nisam, googlao sam i mislio sam da je taj vba to, ali ocigledno nije bio.

hvala bokinet
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument06.08.2018. u 21:13 - pre 68 meseci
Nema na cemu. Nadam se da vrsi posao.
Ako jos nesto ustreba, pisi kao tiket ili na pm slobodno.
Ja kad stignem i uhvatim vremena ako mogu rado cu izaci u susret i pomoci novim snagama u IT.
Ziveli.
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument07.08.2018. u 18:27 - pre 68 meseci
nisam nasao na forumu temu za pdf.

da li postoji mogucnost rename otvorenog pdf?
 
Odgovor na temu

bokinet

Član broj: 29844
Poruke: 574



+50 Profil

icon Re: Rename otvoreni word dokument08.08.2018. u 13:09 - pre 68 meseci
Rad sa PDF fajlovima nije bas isti kao sto se moze raditi u MS Office kroz VBA posto generalno Adobe nema podrska za VBA.

Ako hoces isti princip kao sto si hteo u wordu tesko da je moguce izvesti kroz VBA.

Recimo ako koristis Adobe Acrobat, znam da je pre moglo (nisam skorije nesto po tom pitanju radio) kroz JavaScript da pises kod koji bi mogao da se koristi u Adobe Acrobat i sl.
U nastavku imas js developer guide od Adobe gde mozes da vidis sta je moguce.

js developer guide

U svakom slucaju treba naci poslednji Adobe Acrobat SDK pa videti kako stoje sada stvari.

Dodato:

Evo i linka ka Adobe download cenutr u vezi gore pomenute price:
Adobe download center



[Ovu poruku je menjao bokinet dana 08.08.2018. u 14:20 GMT+1]
 
Odgovor na temu

vojvoda1010
nezaposlen

Član broj: 310516
Poruke: 547
82.208.214.*



+2 Profil

icon Re: Rename otvoreni word dokument17.08.2018. u 18:53 - pre 68 meseci
pokazuje mi dve greske:

pri snimanju imenujem npr. 271.18

i krene da snimi i izbaci



Error in deleting file for given location.

Error 70 - Permission denide.


i nekada


Error in deleting file for given location.

Error 52- Bad file name or number.
 
Odgovor na temu

[es] :: Office :: Word :: Rename otvoreni word dokument

Strane: 1 2

[ Pregleda: 4518 | Odgovora: 26 ] > FB > Twit

Postavi temu Odgovori

Navigacija
Lista poslednjih: 16, 32, 64, 128 poruka.