[es] - Povlačenje cijene

darkos1
banjaluka RS

Član broj: 267138
Poruke: 75
31.223.131.*

+1 Profil

^{14.01.2017. u 15:17 - pre 88 meseci}

Imam cjenovnik prozora sa različitim dimenzijama u exselu.

Upisom originalnih dimenzija lako je dobiti cijenu.

Kako da upisom manje dimenzije a ne postojeće u cjenovniku, da da cijenu prve veće postojeće dimenzije prozora.

Probao sam sa kombinacijom index i match funkcije ali nisam uspio.

Primjer u prilogu.

Prikačeni fajlovi

proba.xlsx - 7.82k

Odgovor na temu

Ivek33

Član broj: 66174
Poruke: 2898

+66 Profil

Re: Povlačenje cijene

^{15.01.2017. u 10:06 - pre 88 meseci}

Probaj ovu ARRAY formulu ispod ako ti odgovara. (Formulu završavaš sa Ctrl+Shift+Enter)

Code:
=INDEX($D$4:$D$15;MATCH(MIN(IF($B$4:$B$15=IFERROR(SMALL($B$4:$B$15;COUNTIF($B$4:$B$15;"<"&F4)+1);LARGE($B$4:$B$15;COUNTIF($B$4:$B$15;">"&F4)+1));ABS($C$4:$C$15-IFERROR(SMALL($C$4:$C$15;COUNTIF($C$4:$C$15;"<"&G4)+1);LARGE($C$4:$C$15;COUNTIF($C$4:$C$15;">"&G4)+1)))));IF($B$4:$B$15=IFERROR(SMALL($B$4:$B$15;COUNTIF($B$4:$B$15;"<"&F4)+1);LARGE($B$4:$B$15;COUNTIF($B$4:$B$15;">"&F4)+1));ABS($C$4:$C$15-IFERROR(SMALL($C$4:$C$15;COUNTIF($C$4:$C$15;"<"&G4)+1);LARGE($C$4:$C$15;COUNTIF($C$4:$C$15;">"&G4)+1))));0)

Vidi primjer u prikačenoj workbook

Prikačeni fajlovi

darkos1-ivek33494327.xlsx - 9.62k

Odgovor na temu

darkos1
banjaluka RS

Član broj: 267138
Poruke: 75
31.223.131.*

+1 Profil

Re: Povlačenje cijene

^{17.01.2017. u 17:24 - pre 88 meseci}

Hvala puno na odgovoru, to je to što sam tražio.

pozzz

Odgovor na temu

Ivek33

Član broj: 66174
Poruke: 2898

+66 Profil

Re: Povlačenje cijene

^{17.01.2017. u 20:44 - pre 88 meseci}

Nema na čemu.
Možeš i ovu kraću ARRAY formulu ali će vratiti error ako prijeđeš max dimenziju (vidi primjer u datoteci)

Code:
=INDEX($D$4:$D$143;MATCH(MIN(IF($B$4:$B$143=SMALL($B$4:$B$143;COUNTIF($B$4:$B$143;"<"&F4)+1);ABS($C$4:$C$143-SMALL($B$4:$B$143;COUNTIF($B$4:$B$143;"<"&G4)+1))));IF($B$4:$B$143=SMALL($B$4:$B$143;COUNTIF($B$4:$B$143;"<"&F4)+1);ABS($C$4:$C$143-SMALL($B$4:$B$143;COUNTIF($B$4:$B$143;"<"&G4)+1)));0))

Naravno ako koristiš imenovane raspone ćelija tada može i ovako

Code:
=INDEX(cijProzor;MATCH(MIN(IF(sirProzor=SMALL(sirProzor;COUNTIF(sirProzor;"<"&F4)+1);ABS(visProzor-SMALL(sirProzor;COUNTIF(sirProzor;"<"&G4)+1))));IF(sirProzor=SMALL(sirProzor;COUNTIF(sirProzor;"<"&F4)+1);ABS(visProzor-SMALL(sirProzor;COUNTIF(sirProzor;"<"&G4)+1)));0))

BTW: Koristeći Data Validation možeš limitirati unos dimenzija.

Ovo je Vlookup formula koja koristi pomoćni stupac A

Code:
=VLOOKUP(SMALL(B$4:B$143;COUNTIF(B$4:B$143;"<"&F4)+1)&SMALL(C$4:C$143;COUNTIF(C$4:C$143;"<"&G4)+1);$A$4:$D$143;4;FALSE)

Prikačeni fajlovi

darkos1-ivek33494327-2.xlsx - 16.36k

darkos1-ivek33494327-imenovane-celije.xlsx - 165.23k

Odgovor na temu